[arch-commits] Commit in haskell-yesod-core/repos (2 files)

[Felix Yan]

    Date: Saturday, December 30, 2017 @ 12:15:24
  Author: felixonmars
Revision: 277124

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod-core/repos/community-staging-x86_64/
  haskell-yesod-core/repos/community-staging-x86_64/PKGBUILD
    (from rev 277123, haskell-yesod-core/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-yesod-core/repos/community-staging-x86_64/PKGBUILD (from rev 277123, haskell-yesod-core/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2017-12-30 12:15:24 UTC (rev 277124)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=yesod-core
+pkgname=haskell-yesod-core
+pkgver=1.4.37.2
+pkgrel=12
+pkgdesc="Creation of type-safe, RESTful web applications."
+url="http://www.yesodweb.com/"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-aeson" "haskell-auto-update" "haskell-blaze-builder" "haskell-blaze-html"
+         "haskell-blaze-markup" "haskell-byteable" "haskell-case-insensitive" "haskell-cereal"
+         "haskell-clientsession" "haskell-conduit" "haskell-conduit-extra" "haskell-cookie"
+         "haskell-data-default" "haskell-deepseq-generics" "haskell-exceptions"
+         "haskell-fast-logger" "haskell-http-types" "haskell-lifted-base" "haskell-monad-control"
+         "haskell-monad-logger" "haskell-mtl" "haskell-mwc-random" "haskell-old-locale"
+         "haskell-parsec" "haskell-path-pieces" "haskell-primitive" "haskell-random"
+         "haskell-resourcet" "haskell-safe" "haskell-semigroups" "haskell-shakespeare"
+         "haskell-text" "haskell-transformers-base" "haskell-unix-compat"
+         "haskell-unordered-containers" "haskell-vector" "haskell-wai" "haskell-wai-extra"
+         "haskell-wai-logger" "haskell-warp" "haskell-word8")
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('712e8e423e532c5a458d948e3d7805c528019fd851ea13ebff2ebec3b7a308309752f3283e5fa27ab408e9e0e5d90f58096db7d05b90be59abecbb4f6a8424db')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}