[arch-commits] Commit in haskell-hasql-transaction/repos (2 files)

[Felix Yan]

    Date: Sunday, December 31, 2017 @ 11:56:08
  Author: felixonmars
Revision: 277556

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hasql-transaction/repos/community-staging-x86_64/
  haskell-hasql-transaction/repos/community-staging-x86_64/PKGBUILD
    (from rev 277555, haskell-hasql-transaction/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-hasql-transaction/repos/community-staging-x86_64/PKGBUILD (from rev 277555, haskell-hasql-transaction/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2017-12-31 11:56:08 UTC (rev 277556)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hasql-transaction
+pkgname=haskell-hasql-transaction
+pkgver=0.5.2
+pkgrel=6
+pkgdesc="A composable abstraction over the retryable transactions for Hasql"
+url="https://github.com/nikita-volkov/hasql-transaction"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-prelude' 'haskell-bytestring-tree-builder'
+         'haskell-contravariant' 'haskell-contravariant-extras' 'haskell-hasql' 'haskell-mtl')
+makedepends=('ghc' 'haskell-async' 'haskell-rebase')
+checkdepends=('postgresql' 'pifpaf')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('be3478b6c62894b517d91b7cbd515ca4fdc750a0dde087bba73ca7e3426e733ca444937136765e526130ce74d112154d444a379f5e5771ec596c404ca19737e2')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+
+    eval $(pifpaf run postgresql --host 127.0.0.1 --port 5432)
+    createuser -s postgres
+    runhaskell Setup test
+    pifpaf_stop
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}