[arch-commits] Commit in (4 files)
Felix Yan
felixonmars at archlinux.org
Thu Feb 9 07:03:57 UTC 2017
Date: Thursday, February 9, 2017 @ 07:03:56
Author: felixonmars
Revision: 211375
addpkg: python-flake8-debugger 1.4.0-1
Added:
python-flake8-debugger/
python-flake8-debugger/repos/
python-flake8-debugger/trunk/
python-flake8-debugger/trunk/PKGBUILD
----------+
PKGBUILD | 51 +++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 51 insertions(+)
Added: python-flake8-debugger/trunk/PKGBUILD
===================================================================
--- python-flake8-debugger/trunk/PKGBUILD (rev 0)
+++ python-flake8-debugger/trunk/PKGBUILD 2017-02-09 07:03:56 UTC (rev 211375)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-flake8-debugger
+pkgname=('python-flake8-debugger' 'python2-flake8-debugger')
+pkgver=1.4.0
+pkgrel=1
+pkgdesc='ipdb/pdb statement checker plugin for flake8'
+arch=('any')
+license=('MIT')
+url='https://github.com/JBKahn/flake8-debugger'
+makedepends=('python-setuptools' 'python2-setuptools' 'flake8' 'python2-flake8' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/JBKahn/flake8-debugger.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+ cp -a flake8-debugger{,-py2}
+}
+
+build() {
+ cd "$srcdir"/flake8-debugger
+ python setup.py build
+
+ cd "$srcdir"/flake8-debugger-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/flake8-debugger
+ python setup.py test
+
+ cd "$srcdir"/flake8-debugger-py2
+ python2 setup.py test
+}
+
+package_python-flake8-debugger() {
+ depends=('flake8')
+
+ cd "$srcdir"/flake8-debugger
+ python setup.py install --root="$pkgdir"/ --optimize=1
+}
+
+package_python2-flake8-debugger() {
+ depends=('python2-flake8')
+
+ cd "$srcdir"/flake8-debugger-py2
+ python2 setup.py install --root="$pkgdir"/ --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:
Property changes on: python-flake8-debugger/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list