[arch-commits] Commit in python-flake8-debugger/repos (2 files)

Felix Yan felixonmars at archlinux.org
Thu Feb 9 07:08:47 UTC 2017


    Date: Thursday, February 9, 2017 @ 07:08:46
  Author: felixonmars
Revision: 211378

archrelease: copy trunk to community-any

Added:
  python-flake8-debugger/repos/community-any/
  python-flake8-debugger/repos/community-any/PKGBUILD
    (from rev 211377, python-flake8-debugger/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: python-flake8-debugger/repos/community-any/PKGBUILD (from rev 211377, python-flake8-debugger/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2017-02-09 07:08:46 UTC (rev 211378)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-flake8-debugger
+pkgname=('python-flake8-debugger' 'python2-flake8-debugger')
+pkgver=1.4.0
+pkgrel=1
+pkgdesc='ipdb/pdb statement checker plugin for flake8'
+arch=('any')
+license=('MIT')
+url='https://github.com/JBKahn/flake8-debugger'
+makedepends=('python-setuptools' 'python2-setuptools' 'flake8' 'python2-flake8' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/JBKahn/flake8-debugger.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a flake8-debugger{,-py2}
+}
+
+build() {
+  cd "$srcdir"/flake8-debugger
+  python setup.py build
+
+  cd "$srcdir"/flake8-debugger-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/flake8-debugger
+  python setup.py test
+
+  cd "$srcdir"/flake8-debugger-py2
+  python2 setup.py test
+}
+
+package_python-flake8-debugger() {
+  depends=('flake8')
+
+  cd "$srcdir"/flake8-debugger
+  python setup.py install --root="$pkgdir"/ --optimize=1
+}
+
+package_python2-flake8-debugger() {
+  depends=('python2-flake8')
+
+  cd "$srcdir"/flake8-debugger-py2
+  python2 setup.py install --root="$pkgdir"/ --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:



More information about the arch-commits mailing list