[arch-commits] Commit in (25 files)

Balló György bgyorgy at archlinux.org
Mon Feb 13 22:47:42 UTC 2017


    Date: Monday, February 13, 2017 @ 22:47:41
  Author: bgyorgy
Revision: 212185

Add Sugar desktop shell ( https://sugarlabs.org/ ) and its dependencies

Added:
  gst-plugins-espeak/
  gst-plugins-espeak/trunk/
  gst-plugins-espeak/trunk/PKGBUILD
  icon-slicer/
  icon-slicer/trunk/
  icon-slicer/trunk/PKGBUILD
  icon-slicer/trunk/hotspotfix.patch
  python2-gwebsockets/
  python2-gwebsockets/trunk/
  python2-gwebsockets/trunk/PKGBUILD
  sugar-artwork/
  sugar-artwork/trunk/
  sugar-artwork/trunk/PKGBUILD
  sugar-datastore/
  sugar-datastore/trunk/
  sugar-datastore/trunk/PKGBUILD
  sugar-runner/
  sugar-runner/trunk/
  sugar-runner/trunk/PKGBUILD
  sugar-toolkit-gtk3/
  sugar-toolkit-gtk3/trunk/
  sugar-toolkit-gtk3/trunk/PKGBUILD
  sugar/
  sugar/trunk/
  sugar/trunk/PKGBUILD

------------------------------------+
 gst-plugins-espeak/trunk/PKGBUILD  |   24 ++++++++++++++++++++++
 icon-slicer/trunk/PKGBUILD         |   35 +++++++++++++++++++++++++++++++++
 icon-slicer/trunk/hotspotfix.patch |   25 +++++++++++++++++++++++
 python2-gwebsockets/trunk/PKGBUILD |   25 +++++++++++++++++++++++
 sugar-artwork/trunk/PKGBUILD       |   27 +++++++++++++++++++++++++
 sugar-datastore/trunk/PKGBUILD     |   29 +++++++++++++++++++++++++++
 sugar-runner/trunk/PKGBUILD        |   25 +++++++++++++++++++++++
 sugar-toolkit-gtk3/trunk/PKGBUILD  |   28 ++++++++++++++++++++++++++
 sugar/trunk/PKGBUILD               |   37 +++++++++++++++++++++++++++++++++++
 9 files changed, 255 insertions(+)

Added: gst-plugins-espeak/trunk/PKGBUILD
===================================================================
--- gst-plugins-espeak/trunk/PKGBUILD	                        (rev 0)
+++ gst-plugins-espeak/trunk/PKGBUILD	2017-02-13 22:47:41 UTC (rev 212185)
@@ -0,0 +1,24 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=gst-plugins-espeak
+pkgver=0.4.0
+pkgrel=1
+pkgdesc="Use espeak as a sound source for gstreamer"
+arch=('i686' 'x86_64')
+url="https://wiki.sugarlabs.org/go/Activity_Team/gst-plugins-espeak"
+license=('LGPL')
+depends=('gst-plugins-base-libs' 'espeak')
+source=(https://download.sugarlabs.org/sources/honey/$pkgname/$pkgname-$pkgver.tar.gz)
+sha256sums=('a7be338a00bc831e69867bcaff99d11f8bff04e58484b9f4f48ccfc69fb9cf9c')
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}


Property changes on: gst-plugins-espeak/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: icon-slicer/trunk/PKGBUILD
===================================================================
--- icon-slicer/trunk/PKGBUILD	                        (rev 0)
+++ icon-slicer/trunk/PKGBUILD	2017-02-13 22:47:41 UTC (rev 212185)
@@ -0,0 +1,35 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=icon-slicer
+pkgver=0.3
+pkgrel=1
+pkgdesc="Utility for generating icon themes and libXcursor cursor themes"
+arch=('i686' 'x86_64')
+url="https://www.freedesktop.org/wiki/Software/icon-slicer/"
+license=('MIT')
+depends=('gdk-pixbuf2' 'popt' 'xorg-xcursorgen')
+source=(https://freedesktop.org/software/icon-slicer/releases/$pkgname-$pkgver.tar.gz
+        hotspotfix.patch)
+sha256sums=('05f0216dd0c25a17859de66357f64da5033375b6fbf5f31ca54867311160b64d'
+            '7000ab887b247f24d22ba225934028b1f5b04c1fb8ceac04d01e925b7a602dd0')
+
+prepare() {
+  cd $pkgname-$pkgver
+  patch -Np1 -i ../hotspotfix.patch
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+
+  # License
+  install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
+  sed '/License/,$!d' README >"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}


Property changes on: icon-slicer/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: icon-slicer/trunk/hotspotfix.patch
===================================================================
--- icon-slicer/trunk/hotspotfix.patch	                        (rev 0)
+++ icon-slicer/trunk/hotspotfix.patch	2017-02-13 22:47:41 UTC (rev 212185)
@@ -0,0 +1,25 @@
+Description: Fix hotspot y coordinate
+Author: Tim Swast <tswast at gmail.com>
+
+--- a/src/main.c
++++ b/src/main.c
+@@ -103,7 +103,7 @@
+   if (n_channels == 3)
+     {
+       out->x = start_x;
+-      out->y = start_x;
++      out->y = start_y;
+       out->width = source->gridsize;
+       out->height = source->gridsize;
+       
+@@ -137,8 +137,8 @@
+ 		    {
+ 		      min_x = start_x + i;
+ 		      max_x = start_x + i + 1;
+-		      min_y = start_y + i;
+-		      max_y = start_y + i + 1;
++		      min_y = start_y + j;
++		      max_y = start_y + j + 1;
+ 
+ 		      found = TRUE;
+ 		    }

Added: python2-gwebsockets/trunk/PKGBUILD
===================================================================
--- python2-gwebsockets/trunk/PKGBUILD	                        (rev 0)
+++ python2-gwebsockets/trunk/PKGBUILD	2017-02-13 22:47:41 UTC (rev 212185)
@@ -0,0 +1,25 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=python2-gwebsockets
+_pkgname=gwebsockets
+pkgver=0.4
+pkgrel=1
+pkgdesc="GLib based websocket server written in python"
+arch=('any')
+url="https://github.com/dnarvaez/gwebsockets"
+license=('Apache')
+depends=('python2-gobject')
+makedepends=('python2-setuptools')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/dnarvaez/$_pkgname/archive/v$pkgver.tar.gz")
+sha256sums=('001d42a7d3adf2613f29e072a6488048c93800af3e3288df1c24e3e69da7e7e9')
+
+build() {
+  cd $_pkgname-$pkgver
+  python2 setup.py build
+}
+
+package() {
+  cd $_pkgname-$pkgver
+  python2 setup.py install --root "$pkgdir" --optimize=1
+}


Property changes on: python2-gwebsockets/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: sugar/trunk/PKGBUILD
===================================================================
--- sugar/trunk/PKGBUILD	                        (rev 0)
+++ sugar/trunk/PKGBUILD	2017-02-13 22:47:41 UTC (rev 212185)
@@ -0,0 +1,37 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=sugar
+pkgver=0.110.0
+pkgrel=1
+pkgdesc="Sugar GTK shell"
+arch=('any')
+url="https://sugarlabs.org/"
+license=('GPL')
+depends=('gconf' 'gnome-keyring' 'gst-plugins-espeak' 'gtksourceview3' 'gvfs' 'libwnck3'
+         'libxklavier' 'metacity' 'mobile-broadband-provider-info' 'openssh' 'python2-gwebsockets'
+         'sugar-toolkit-gtk3' 'telepathy-gabble' 'telepathy-salut' 'upower' 'webkit2gtk'
+         'xdg-user-dirs')
+makedepends=('intltool')
+source=(https://download.sugarlabs.org/sources/sucrose/glucose/$pkgname/$pkgname-$pkgver.tar.xz)
+sha256sums=('c5b662442a404f4dab7f67514aae5f887533262e4a98aa4b4c675e4f63b2203d')
+
+prepare() {
+  cd $pkgname-$pkgver
+  sed -i 's@^#!.*python$@#!/usr/bin/python2@' src/jarabe/model/update/aslo.py
+  sed -i "s/gi.require_version('WebKit', '3.0')/gi.require_version('WebKit2', '4.0')/" src/jarabe/main.py
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr --sysconfdir=/etc \
+              --disable-schemas-install --disable-schemas-compile \
+              --with-gconf-schema-file-dir=/usr/share/gconf/schemas
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+  rm -r "$pkgdir"/usr/share/sugar/extensions/cpsection/updater/
+}


Property changes on: sugar/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: sugar-artwork/trunk/PKGBUILD
===================================================================
--- sugar-artwork/trunk/PKGBUILD	                        (rev 0)
+++ sugar-artwork/trunk/PKGBUILD	2017-02-13 22:47:41 UTC (rev 212185)
@@ -0,0 +1,27 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=sugar-artwork
+pkgver=0.110.0
+pkgrel=1
+pkgdesc="Sugar icons and themes"
+arch=('i686' 'x86_64')
+url="https://sugarlabs.org/"
+license=('LGPL')
+makedepends=('gtk2' 'gtk3' 'icon-naming-utils' 'icon-slicer' 'python2')
+optdepends=('gtk2: GTK+ 2 theme'
+            'gtk3: GTK+ 3 theme')
+source=(https://download.sugarlabs.org/sources/sucrose/glucose/$pkgname/$pkgname-$pkgver.tar.xz)
+sha256sums=('361f118cac914686d30925b13bd55fa2f8f19009aaacbe6dc59dce4d9c7c7837')
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr
+  sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}


Property changes on: sugar-artwork/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: sugar-datastore/trunk/PKGBUILD
===================================================================
--- sugar-datastore/trunk/PKGBUILD	                        (rev 0)
+++ sugar-datastore/trunk/PKGBUILD	2017-02-13 22:47:41 UTC (rev 212185)
@@ -0,0 +1,29 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=sugar-datastore
+pkgver=0.110.0
+pkgrel=1
+pkgdesc="Sugar datastore service"
+arch=('i686' 'x86_64')
+url="https://sugarlabs.org/"
+license=('GPL')
+depends=('python2-dbus' 'python2-gobject' 'python2-xapian')
+source=(https://download.sugarlabs.org/sources/sucrose/glucose/$pkgname/$pkgname-$pkgver.tar.xz)
+sha256sums=('b3d8527a196c48688eb2395f13338c2c84b104e44db7e7520597f67135af0458')
+
+prepare() {
+  cd $pkgname-$pkgver
+  sed -i 's@^#!.*python$@#!/usr/bin/python2@' bin/copy-to-journal
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}


Property changes on: sugar-datastore/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: sugar-runner/trunk/PKGBUILD
===================================================================
--- sugar-runner/trunk/PKGBUILD	                        (rev 0)
+++ sugar-runner/trunk/PKGBUILD	2017-02-13 22:47:41 UTC (rev 212185)
@@ -0,0 +1,25 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=sugar-runner
+pkgver=0.110.0
+pkgrel=1
+pkgdesc="Scripts to run Sugar"
+arch=('i686' 'x86_64')
+url="https://sugarlabs.org/"
+license=('GPL')
+depends=('sugar' 'xorg-xinit' 'xorg-server-xephyr' 'xorg-xrandr')
+makedepends=('gobject-introspection')
+source=(https://download.sugarlabs.org/sources/sucrose/glucose/$pkgname/$pkgname-$pkgver.tar.xz)
+sha256sums=('383db309d4444f4758892b57614ace47d7cc395fdf01d1894d3da94354ff6870')
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr --libexecdir=/usr/lib
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}


Property changes on: sugar-runner/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: sugar-toolkit-gtk3/trunk/PKGBUILD
===================================================================
--- sugar-toolkit-gtk3/trunk/PKGBUILD	                        (rev 0)
+++ sugar-toolkit-gtk3/trunk/PKGBUILD	2017-02-13 22:47:41 UTC (rev 212185)
@@ -0,0 +1,28 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=sugar-toolkit-gtk3
+pkgver=0.110.0
+pkgrel=1
+pkgdesc="Sugar GTK library"
+arch=('i686' 'x86_64')
+url="https://sugarlabs.org/"
+license=('LGPL')
+depends=('alsa-lib' 'gtk3' 'libsm' 'python2-cairo' 'python2-dateutil' 'python2-decorator'
+         'python2-telepathy' 'sugar-artwork' 'sugar-datastore' 'telepathy-mission-control' 'unzip')
+makedepends=('intltool' 'gobject-introspection')
+optdepends=('webkit2gtk: run sugar-activity-web')
+source=(https://download.sugarlabs.org/sources/sucrose/glucose/$pkgname/$pkgname-$pkgver.tar.xz)
+sha256sums=('e4b626c4efb515a444eb7bc2d5897aca1affd710f328de95b426f9f13032373e')
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr
+  sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}


Property changes on: sugar-toolkit-gtk3/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list