[arch-commits] Commit in powerdns/repos (6 files)
Bartłomiej Piotrowski
bpiotrowski at archlinux.org
Mon Jan 2 09:38:30 UTC 2017
Date: Monday, January 2, 2017 @ 09:38:29
Author: bpiotrowski
Revision: 204227
archrelease: copy trunk to community-staging-i686, community-staging-x86_64
Added:
powerdns/repos/community-staging-i686/
powerdns/repos/community-staging-i686/PKGBUILD
(from rev 204226, powerdns/trunk/PKGBUILD)
powerdns/repos/community-staging-i686/powerdns.install
(from rev 204226, powerdns/trunk/powerdns.install)
powerdns/repos/community-staging-x86_64/
powerdns/repos/community-staging-x86_64/PKGBUILD
(from rev 204226, powerdns/trunk/PKGBUILD)
powerdns/repos/community-staging-x86_64/powerdns.install
(from rev 204226, powerdns/trunk/powerdns.install)
-------------------------------------------+
community-staging-i686/PKGBUILD | 95 ++++++++++++++++++++++++++++
community-staging-i686/powerdns.install | 10 ++
community-staging-x86_64/PKGBUILD | 95 ++++++++++++++++++++++++++++
community-staging-x86_64/powerdns.install | 10 ++
4 files changed, 210 insertions(+)
Copied: powerdns/repos/community-staging-i686/PKGBUILD (from rev 204226, powerdns/trunk/PKGBUILD)
===================================================================
--- community-staging-i686/PKGBUILD (rev 0)
+++ community-staging-i686/PKGBUILD 2017-01-02 09:38:29 UTC (rev 204227)
@@ -0,0 +1,95 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Kevin Mihelich <kevin at archlinuxarm.org>
+# Contributor: Remi Gacogne <rgacogne[at]archlinux[dot]org>
+
+pkgname=powerdns
+pkgver=4.0.1
+pkgrel=6
+pkgdesc='Authoritative DNS server'
+url='http://www.powerdns.com/'
+arch=('i686' 'x86_64')
+license=('GPL2')
+depends=('boost-libs' 'libsodium' 'systemd' 'lua' 'openssl' 'protobuf' 'sqlite')
+makedepends=('boost' 'setconf' 'libmariadbclient' 'postgresql-libs' 'lua' 'libldap'
+ 'sqlite' 'geoip' 'yaml-cpp' 'pkg-config')
+optdepends=('libmariadbclient: MariaDB/MySQL backend'
+ 'postgresql-libs: PostgreSQL backend'
+ 'libldap: LDAP backend'
+ 'geoip: GeoIP backend'
+ 'yaml-cpp: GeoIP backend')
+provides=('pdns')
+conflicts=('pdns')
+backup=('etc/powerdns/pdns.conf')
+install=powerdns.install
+source=(https://downloads.powerdns.com/releases/pdns-${pkgver}.tar.bz2{,.asc})
+sha512sums=('77fce9963a05198afeb569f92fbb0f6a1cb3426c28dd77b0921128189c80d9a72ebdbfc249dfc0b5b89cc7a65a83887a0388d6cc3461453b1e3096e563afdd1e'
+ 'SKIP')
+validpgpkeys=('B76CD4671C0968BAA87DE61C5E50715BF2FFE1A7') # Pieter Lexis <pieter.lexis at powerdns.com>
+
+prepare() {
+ cd pdns-${pkgver}
+
+ # Default settings
+ for keyvalue in \
+ allow-recursion=127.0.0.1 \
+ chroot=/var/empty \
+ config-dir=/etc/powerdns \
+ daemon=no \
+ distributor-threads=3 \
+ guardian=no \
+ local-port=53 \
+ loglevel=3 \
+ module-dir=/usr/lib/powerdns \
+ setgid=nobody \
+ setuid=nobody \
+ socket-dir=/var/run \
+ webserver=no
+ do
+ setconf -a pdns.conf "${keyvalue}"
+ done
+
+ # Using simple so we can bind it to a chroot
+ sed 's|notify|simple|' -i pdns/pdns.service.in
+}
+
+build() {
+ cd pdns-${pkgver}
+ ./configure \
+ --prefix=/usr \
+ --sysconfdir=/etc/powerdns \
+ --libexecdir=/usr/lib \
+ --libdir=/usr/lib \
+ --mandir=/usr/share/man \
+ --with-modules='' \
+ --with-dynmodules="bind gmysql geoip gpgsql gsqlite3 ldap lua pipe random remote" \
+ --docdir=/usr/share/doc/powerdns \
+ --sbindir=/usr/bin \
+ --bindir=/usr/bin \
+ --with-sqlite3 \
+ --enable-libsodium \
+ --enable-tools \
+ --disable-dependency-tracking \
+ --disable-silent-rules \
+ --enable-reproducible \
+ --enable-unit-tests \
+ --enable-systemd
+ make
+}
+
+check() {
+ make -C pdns-${pkgver} check
+}
+
+package() {
+ cd pdns-${pkgver}
+ make DESTDIR="${pkgdir}" install
+ # apply defaults to generated pdns.conf
+ mv "${pkgdir}/etc/powerdns/pdns.conf"{-dist,}
+ cat pdns.conf >> "${pkgdir}/etc/powerdns/pdns.conf"
+ # adjust modules dir to match pkgname
+ mv "${pkgdir}/usr/lib/"{pdns,powerdns}
+}
+
+# vim: ts=2 sw=2 et:
Copied: powerdns/repos/community-staging-i686/powerdns.install (from rev 204226, powerdns/trunk/powerdns.install)
===================================================================
--- community-staging-i686/powerdns.install (rev 0)
+++ community-staging-i686/powerdns.install 2017-01-02 09:38:29 UTC (rev 204227)
@@ -0,0 +1,10 @@
+post_upgrade() {
+ echo
+ echo 'See http://doc.powerdns.com/md/authoritative/upgrading/ for'
+ echo 'information about changes when upgrading.'
+ echo
+ echo 'WARNING: powerdns.service has been renamed back to pdns.service.'
+ echo
+}
+
+# vim: ts=2 sw=2 et:
Copied: powerdns/repos/community-staging-x86_64/PKGBUILD (from rev 204226, powerdns/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2017-01-02 09:38:29 UTC (rev 204227)
@@ -0,0 +1,95 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Kevin Mihelich <kevin at archlinuxarm.org>
+# Contributor: Remi Gacogne <rgacogne[at]archlinux[dot]org>
+
+pkgname=powerdns
+pkgver=4.0.1
+pkgrel=6
+pkgdesc='Authoritative DNS server'
+url='http://www.powerdns.com/'
+arch=('i686' 'x86_64')
+license=('GPL2')
+depends=('boost-libs' 'libsodium' 'systemd' 'lua' 'openssl' 'protobuf' 'sqlite')
+makedepends=('boost' 'setconf' 'libmariadbclient' 'postgresql-libs' 'lua' 'libldap'
+ 'sqlite' 'geoip' 'yaml-cpp' 'pkg-config')
+optdepends=('libmariadbclient: MariaDB/MySQL backend'
+ 'postgresql-libs: PostgreSQL backend'
+ 'libldap: LDAP backend'
+ 'geoip: GeoIP backend'
+ 'yaml-cpp: GeoIP backend')
+provides=('pdns')
+conflicts=('pdns')
+backup=('etc/powerdns/pdns.conf')
+install=powerdns.install
+source=(https://downloads.powerdns.com/releases/pdns-${pkgver}.tar.bz2{,.asc})
+sha512sums=('77fce9963a05198afeb569f92fbb0f6a1cb3426c28dd77b0921128189c80d9a72ebdbfc249dfc0b5b89cc7a65a83887a0388d6cc3461453b1e3096e563afdd1e'
+ 'SKIP')
+validpgpkeys=('B76CD4671C0968BAA87DE61C5E50715BF2FFE1A7') # Pieter Lexis <pieter.lexis at powerdns.com>
+
+prepare() {
+ cd pdns-${pkgver}
+
+ # Default settings
+ for keyvalue in \
+ allow-recursion=127.0.0.1 \
+ chroot=/var/empty \
+ config-dir=/etc/powerdns \
+ daemon=no \
+ distributor-threads=3 \
+ guardian=no \
+ local-port=53 \
+ loglevel=3 \
+ module-dir=/usr/lib/powerdns \
+ setgid=nobody \
+ setuid=nobody \
+ socket-dir=/var/run \
+ webserver=no
+ do
+ setconf -a pdns.conf "${keyvalue}"
+ done
+
+ # Using simple so we can bind it to a chroot
+ sed 's|notify|simple|' -i pdns/pdns.service.in
+}
+
+build() {
+ cd pdns-${pkgver}
+ ./configure \
+ --prefix=/usr \
+ --sysconfdir=/etc/powerdns \
+ --libexecdir=/usr/lib \
+ --libdir=/usr/lib \
+ --mandir=/usr/share/man \
+ --with-modules='' \
+ --with-dynmodules="bind gmysql geoip gpgsql gsqlite3 ldap lua pipe random remote" \
+ --docdir=/usr/share/doc/powerdns \
+ --sbindir=/usr/bin \
+ --bindir=/usr/bin \
+ --with-sqlite3 \
+ --enable-libsodium \
+ --enable-tools \
+ --disable-dependency-tracking \
+ --disable-silent-rules \
+ --enable-reproducible \
+ --enable-unit-tests \
+ --enable-systemd
+ make
+}
+
+check() {
+ make -C pdns-${pkgver} check
+}
+
+package() {
+ cd pdns-${pkgver}
+ make DESTDIR="${pkgdir}" install
+ # apply defaults to generated pdns.conf
+ mv "${pkgdir}/etc/powerdns/pdns.conf"{-dist,}
+ cat pdns.conf >> "${pkgdir}/etc/powerdns/pdns.conf"
+ # adjust modules dir to match pkgname
+ mv "${pkgdir}/usr/lib/"{pdns,powerdns}
+}
+
+# vim: ts=2 sw=2 et:
Copied: powerdns/repos/community-staging-x86_64/powerdns.install (from rev 204226, powerdns/trunk/powerdns.install)
===================================================================
--- community-staging-x86_64/powerdns.install (rev 0)
+++ community-staging-x86_64/powerdns.install 2017-01-02 09:38:29 UTC (rev 204227)
@@ -0,0 +1,10 @@
+post_upgrade() {
+ echo
+ echo 'See http://doc.powerdns.com/md/authoritative/upgrading/ for'
+ echo 'information about changes when upgrading.'
+ echo
+ echo 'WARNING: powerdns.service has been renamed back to pdns.service.'
+ echo
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list