[arch-commits] Commit in ruby-packetfu/repos (2 files)

[Evangelos Foutras]

    Date: Monday, January 9, 2017 @ 23:38:02
  Author: foutrelis
Revision: 206274

archrelease: copy trunk to community-staging-any

Added:
  ruby-packetfu/repos/community-staging-any/
  ruby-packetfu/repos/community-staging-any/PKGBUILD
    (from rev 206273, ruby-packetfu/trunk/PKGBUILD)

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Copied: ruby-packetfu/repos/community-staging-any/PKGBUILD (from rev 206273, ruby-packetfu/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2017-01-09 23:38:02 UTC (rev 206274)
@@ -0,0 +1,36 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+_gemname=packetfu
+pkgname=ruby-${_gemname}
+pkgver=1.1.11
+pkgrel=3
+pkgdesc='Library for reading and writing packets to an interface or to a libpcap-formatted file'
+url='https://github.com/packetfu/packetfu'
+arch=('any')
+license=('BSD')
+depends=('ruby' 'ruby-network_interface' 'ruby-pcaprub')
+options=('!emptydirs')
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/packetfu/packetfu/archive/version-${pkgver}.tar.gz)
+sha512sums=('c1144b11e3b4020a96ad7a73b299b06fbe51a8e0a81ff2ddbef8f82268bbe2edd8497eb4f69cb66078ce724e41d0d1105571e0462794d11ca42b7da573753837')
+
+prepare() {
+  cd ${_gemname}-version-${pkgver}
+  sed 's|git ls-files|find|' -i ${_gemname}.gemspec
+  sed -r 's|~>|>=|g' -i ${_gemname}.gemspec
+}
+
+build() {
+  cd ${_gemname}-version-${pkgver}
+  gem build ${_gemname}.gemspec
+}
+
+package() {
+  cd ${_gemname}-version-${pkgver}
+  local _gemdir="$(gem env gemdir)"
+  gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
+  install -Dm 644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm 644 README.rdoc -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 examples/* -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
+}
+
+# vim: ts=2 sw=2 et: