[arch-commits] Commit in python-pysaml2 (trunk trunk/PKGBUILD)

[Johannes Löthberg]

    Date: Saturday, January 21, 2017 @ 19:49:53
  Author: demize
Revision: 208321

upgpkg: python-pysaml2 4.4.0-1

Added:
  python-pysaml2/trunk/
  python-pysaml2/trunk/PKGBUILD

----------+
 PKGBUILD |   66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

Added: trunk/PKGBUILD
===================================================================
--- trunk/PKGBUILD	                        (rev 0)
+++ trunk/PKGBUILD	2017-01-21 19:49:53 UTC (rev 208321)
@@ -0,0 +1,66 @@
+# Maintainer: Johannes Löthberg <johannes at kyriasis.com>
+# Contributor: Ivan Shapovalov <intelfx at intelfx.name>
+
+pkgbase=python-pysaml2
+pkgname=(python-pysaml2 python2-pysaml2)
+pkgver=4.4.0
+pkgrel=1
+
+pkgdesc='Python implementation of SAML Version 2'
+url='https://pypi.python.org/pypi/pysaml2'
+arch=('any')
+license=('Apache')
+
+makedepends=('python-setuptools'
+             'python2-setuptools')
+
+source=("https://pypi.org/packages/source/p/pysaml2/pysaml2-$pkgver.tar.gz")
+
+md5sums=('401a34fd919f0f95efaa1e34a59bcbf9')
+
+prepare() {
+	cp -a pysaml2-$pkgver{,-python2}
+}
+
+build() {
+	cd "$srcdir"/pysaml2-$pkgver
+	python setup.py build
+
+	cd "$srcdir"/pysaml2-$pkgver-python2
+	python2 setup.py build
+}
+
+package_python-pysaml2() {
+	depends=('python'
+	         'python-future'
+	         'python-requests'
+	         'python-zope-interface'
+	         'python-pycryptodomex'
+	         'python-pytz'
+	         'python-pyopenssl'
+	         'python-dateutil'
+	         'python-six')
+
+	cd pysaml2-$pkgver
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}
+
+package_python2-pysaml2() {
+	depends=('python2'
+	         'python2-future'
+	         'python2-requests'
+	         'python2-zope-interface'
+	         'python2-pycryptodomex'
+	         'python2-pytz'
+	         'python2-pyopenssl'
+	         'python2-dateutil'
+	         'python2-six')
+
+	cd pysaml2-$pkgver-python2
+	python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+	# rename all executables
+	find "$pkgdir"/usr/bin -type f -exec mv {} {}2 \;
+}
+
+# vim: set ts=4 sw=4 tw=0 ft=PKGBUILD :


Property changes on: python-pysaml2/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property