[arch-commits] Commit in python-acme/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Sun Jan 29 02:56:49 UTC 2017
Date: Sunday, January 29, 2017 @ 02:56:48
Author: felixonmars
Revision: 209327
archrelease: copy trunk to community-staging-any
Added:
python-acme/repos/community-staging-any/
python-acme/repos/community-staging-any/PKGBUILD
(from rev 209326, python-acme/trunk/PKGBUILD)
----------+
PKGBUILD | 57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 57 insertions(+)
Copied: python-acme/repos/community-staging-any/PKGBUILD (from rev 209326, python-acme/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2017-01-29 02:56:48 UTC (rev 209327)
@@ -0,0 +1,57 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Gordian Edenhofer <gordian.edenhofer[at]yahoo[dot]de>
+
+pkgbase=python-acme
+pkgname=('python-acme' 'python2-acme')
+pkgver=0.10.2
+pkgrel=1
+pkgdesc="ACME protocol implementation in Python"
+arch=('any')
+license=('Apache')
+url="https://github.com/letsencrypt/letsencrypt"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pyopenssl' 'python2-pyopenssl'
+ 'python-pyrfc3339' 'python2-pyrfc3339' 'python-pytz' 'python2-pytz' 'python-requests'
+ 'python2-requests' 'python-six' 'python2-six' 'python-werkzeug' 'python2-werkzeug'
+ 'python-mock' 'python2-mock')
+checkdepends=('python-nose' 'python2-nose')
+source=("https://pypi.io/packages/source/a/acme/acme-$pkgver.tar.gz")
+sha512sums=('03c402fa3ae80b1d432d4e5e952a56285983c79049823b6ce7dcb0eb692a91afece3a93d3d1c7f739ba6d59aa9d160c1db2a4adabe05f07ac829dcead24c2a8a')
+
+prepare() {
+ cp -a acme-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir"/acme-$pkgver
+ python setup.py build
+
+ cd "$srcdir"/acme-$pkgver-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/acme-$pkgver
+ python setup.py nosetests
+
+ cd "$srcdir"/acme-$pkgver-py2
+ python2 setup.py nosetests
+}
+
+package_python-acme() {
+ depends=('python-setuptools' 'python-pyopenssl' 'python-pyrfc3339' 'python-pytz' 'python-requests'
+ 'python-six' 'python-werkzeug' 'python-mock')
+
+ cd acme-$pkgver
+ python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-acme() {
+ depends=('python2-setuptools' 'python2-pyopenssl' 'python2-pyrfc3339' 'python2-pytz'
+ 'python2-requests' 'python2-six' 'python2-werkzeug' 'python2-mock')
+
+ cd acme-$pkgver-py2
+ python2 setup.py install --root="$pkgdir" --optimize=1
+
+ mv "$pkgdir"/usr/bin/jws{,2}
+}
More information about the arch-commits
mailing list