[arch-commits] Commit in python-acme/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Fri Jul 7 05:43:11 UTC 2017
Date: Friday, July 7, 2017 @ 05:43:10
Author: felixonmars
Revision: 242613
archrelease: copy trunk to community-staging-any
Added:
python-acme/repos/community-staging-any/
python-acme/repos/community-staging-any/PKGBUILD
(from rev 242612, python-acme/trunk/PKGBUILD)
----------+
PKGBUILD | 58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 58 insertions(+)
Copied: python-acme/repos/community-staging-any/PKGBUILD (from rev 242612, python-acme/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2017-07-07 05:43:10 UTC (rev 242613)
@@ -0,0 +1,58 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Gordian Edenhofer <gordian.edenhofer[at]yahoo[dot]de>
+
+pkgbase=python-acme
+pkgname=('python-acme' 'python2-acme')
+pkgver=0.16.0
+pkgrel=1
+pkgdesc="ACME protocol implementation in Python"
+arch=('any')
+license=('Apache')
+url="https://github.com/certbot/certbot"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pyopenssl' 'python2-pyopenssl'
+ 'python-pyrfc3339' 'python2-pyrfc3339' 'python-pytz' 'python2-pytz' 'python-requests'
+ 'python2-requests' 'python-six' 'python2-six' 'python-werkzeug' 'python2-werkzeug'
+ 'python-mock' 'python2-mock')
+checkdepends=('python-nose' 'python2-nose')
+source=("https://pypi.io/packages/source/a/acme/acme-$pkgver.tar.gz")
+sha512sums=('20fcb3bc16bc7fd556344266f031a1e581b289793e35c38ed135acfb98d44fc06ad4d465dc68a78b0b0b850083a289922a59eefd2a832342db4d022a97c19253')
+
+prepare() {
+ sed -i "/'argparse',/d" acme-$pkgver/setup.py
+ cp -a acme-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir"/acme-$pkgver
+ python setup.py build
+
+ cd "$srcdir"/acme-$pkgver-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/acme-$pkgver
+ python setup.py nosetests
+
+ cd "$srcdir"/acme-$pkgver-py2
+ python2 setup.py nosetests
+}
+
+package_python-acme() {
+ depends=('python-setuptools' 'python-pyopenssl' 'python-pyrfc3339' 'python-pytz' 'python-requests'
+ 'python-six' 'python-werkzeug' 'python-mock')
+
+ cd acme-$pkgver
+ python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-acme() {
+ depends=('python2-setuptools' 'python2-pyopenssl' 'python2-pyrfc3339' 'python2-pytz'
+ 'python2-requests' 'python2-six' 'python2-werkzeug' 'python2-mock')
+
+ cd acme-$pkgver-py2
+ python2 setup.py install --root="$pkgdir" --optimize=1
+
+ mv "$pkgdir"/usr/bin/jws{,2}
+}
More information about the arch-commits
mailing list