[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Tuesday, July 11, 2017 @ 14:28:15
  Author: felixonmars
Revision: 244260

addpkg: haskell-wai-cors 0.2.5-1

Added:
  haskell-wai-cors/
  haskell-wai-cors/repos/
  haskell-wai-cors/trunk/
  haskell-wai-cors/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: haskell-wai-cors/trunk/PKGBUILD
===================================================================
--- haskell-wai-cors/trunk/PKGBUILD	                        (rev 0)
+++ haskell-wai-cors/trunk/PKGBUILD	2017-07-11 14:28:15 UTC (rev 244260)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=wai-cors
+pkgname=haskell-wai-cors
+pkgver=0.2.5
+pkgrel=1
+pkgdesc="CORS for WAI"
+url="https://github.com/larskuhtz/wai-cors"
+license=("MIT")
+arch=('i686' 'x86_64')
+depends=('ghc' "haskell-attoparsec" "haskell-base-unicode-symbols" "haskell-case-insensitive"
+         "haskell-http-types" "haskell-wai" "haskell-mtl")
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha256sums=('25089b8a043e0eb042ef63070ddd7ecc4d961c74526c9c00b292eda4b92d766e')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup haddock --hoogle --html
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    install -d -m755 "${pkgdir}/usr/share/doc/ghc/html/libraries"
+    ln -s "/usr/share/doc/${pkgname}/html" "${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+
+    # Remove static libs
+    find "$pkgdir"/usr/lib -name "*.a" -delete
+}


Property changes on: haskell-wai-cors/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property