[arch-commits] Commit in (3 files)

[Massimiliano Torromeo]

    Date: Monday, June 12, 2017 @ 12:44:58
  Author: mtorromeo
Revision: 236402

Add nginx-mod-memc

Added:
  nginx-mod-memc/
  nginx-mod-memc/trunk/
  nginx-mod-memc/trunk/PKGBUILD

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Added: nginx-mod-memc/trunk/PKGBUILD
===================================================================
--- nginx-mod-memc/trunk/PKGBUILD	                        (rev 0)
+++ nginx-mod-memc/trunk/PKGBUILD	2017-06-12 12:44:58 UTC (rev 236402)
@@ -0,0 +1,39 @@
+# $Id$
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgname=nginx-mod-memc
+pkgver=0.18
+pkgrel=1
+
+_modname="${pkgname#nginx-mod-}"
+_nginxver=1.12.0
+
+pkgdesc='Extended version of the standard memcached module for nginx'
+arch=('i686' 'x86_64')
+depends=("nginx=$_nginxver")
+url="https://github.com/openresty/memc-nginx-module"
+license=('BSD')
+
+source=(
+	http://nginx.org/download/nginx-$_nginxver.tar.gz
+	https://github.com/openresty/$_modname-nginx-module/archive/v$pkgver/$_modname-$pkgver.tar.gz
+)
+
+sha256sums=('b4222e26fdb620a8d3c3a3a8b955e08b713672e1bc5198d1e4f462308a795b30'
+            '4e280d1dcb8b312bc7875604c1e35b17879279126d3d5fbf482aa9cc7c11276d')
+
+build() {
+	cd "$srcdir"/nginx-$_nginxver
+	./configure $(nginx -V 2>&1 | grep 'configure arguments' | sed -r 's@^[^:]+: @@') --add-dynamic-module=../$_modname-nginx-module-$pkgver
+	make modules
+}
+
+package() {
+	cd "$srcdir"/nginx-$_nginxver/objs
+	for mod in *.so; do
+		install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
+	done
+
+	install -Dm644 "$srcdir"/$_modname-nginx-module-$pkgver/README.markdown \
+	               "$pkgdir"/usr/share/licenses/$pkgname/README.markdown
+}


Property changes on: nginx-mod-memc/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property