[arch-commits] Commit in (3 files)

[Massimiliano Torromeo]

    Date: Monday, June 12, 2017 @ 14:54:13
  Author: mtorromeo
Revision: 236536

Add libmaxminddb and mmdblookup

Added:
  libmaxminddb/
  libmaxminddb/trunk/
  libmaxminddb/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: libmaxminddb/trunk/PKGBUILD
===================================================================
--- libmaxminddb/trunk/PKGBUILD	                        (rev 0)
+++ libmaxminddb/trunk/PKGBUILD	2017-06-12 14:54:13 UTC (rev 236536)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+# Contributor: frank AT apsu DOT be
+
+pkgname=(libmaxminddb mmdblookup)
+
+pkgver=1.2.1
+pkgrel=1
+pkgdesc="MaxMind GeoIP2 database - split package with library and utilities"
+license=('Apache')
+arch=('i686' 'x86_64')
+url="http://dev.maxmind.com/geoip/geoip2/downloadable/"
+optdepends=('geoip2-database: IP geolocation databases')
+source=("https://github.com/maxmind/libmaxminddb/releases/download/$pkgver/libmaxminddb-$pkgver.tar.gz")
+sha256sums=('9fa2b3341c9c88117f58454dfb2dd104915a337d93c8a9a735931a63b37f7bfa')
+
+build() {
+	cd "$srcdir"/libmaxminddb-$pkgver
+	./configure --prefix=/usr
+	make
+}
+
+check() {
+	cd "$srcdir"/libmaxminddb-$pkgver
+	make check
+}
+
+package_libmaxminddb() {
+	pkgdesc="MaxMindDB GeoIP2 database library"
+	depends=('glibc')
+
+	cd "$srcdir"/libmaxminddb-$pkgver
+	make PREFIX=/usr DESTDIR="$pkgdir" install
+	rm -rf "$pkgdir"/usr/{bin,share/man/man1}
+}
+
+package_mmdblookup() {
+	pkgdesc="MaxMindDB GeoIP2 lookup utility"
+	depends=('libmaxminddb')
+
+	cd "$srcdir"/libmaxminddb-$pkgver
+	make PREFIX=/usr DESTDIR="$pkgdir" install
+	rm -rf "$pkgdir"/usr/{lib,include,share/man/man3}
+}


Property changes on: libmaxminddb/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property