[arch-commits] Commit in python-gitdb/trunk (PKGBUILD)

[NicoHood]

    Date: Tuesday, June 13, 2017 @ 18:04:54
  Author: nicohood
Revision: 236666

upgpkg: python-gitdb 2.0.2-1

Modified:
  python-gitdb/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2017-06-13 18:00:32 UTC (rev 236665)
+++ PKGBUILD	2017-06-13 18:04:54 UTC (rev 236666)
@@ -0,0 +1,48 @@
+# Maintainer: NicoHood <archlinux {cat} nicohood {dog} de>
+# PGP ID: 97312D5EB9D7AE7D0BD4307351DAE9B7C1AE9161
+# Contributor: Carl George < arch at cgtx dot us >
+
+_pkgname=python-gitdb
+_pypiname=gitdb2
+pkgbase=python-gitdb
+pkgdesc="A pure-Python git object database"
+pkgname=('python-gitdb' 'python2-gitdb')
+pkgver=2.0.2
+pkgrel=1
+url="https://github.com/gitpython-developers/gitdb"
+license=('BSD')
+arch=("any")
+makedepends=('python' 'python-setuptools' 'python2' 'python2-setuptools')
+source=("${_pkgname}-${pkgver}.tar.gz::https://pypi.org/packages/source/g/${_pypiname}/${_pypiname}-${pkgver}.tar.gz"
+        "${_pkgname}-${pkgver}.tar.gz.asc::https://pypi.org/packages/source/g/${_pypiname}/${_pypiname}-${pkgver}.tar.gz.asc")
+sha512sums=('685af97dcb1f352255024b8a382255dacea00aa6312f71d2a16eab00d0204ebf6d46c90d804a4778ea0ef35eae7e5a2f5ae71c16851206fdaf27be8af59499d9'
+            'SKIP')
+validpgpkeys=('4477ADC5977D7C60D2A7E3789FEE1C6A3B07188F') # Sebastian Thiel (In Rust I trust!) <byronimo at gmail.com>
+
+prepare() {
+    cp -a "${srcdir}/${_pypiname}-${pkgver}"{,-py2}
+}
+
+build() {
+    cd "${srcdir}/${_pypiname}-${pkgver}"
+    python setup.py build
+
+    cd "${srcdir}/${_pypiname}-${pkgver}-py2"
+    python2 setup.py build
+}
+
+package_python-gitdb() {
+    depends=('python' 'python-smmap>=2.0.0')
+
+    cd "${srcdir}/${_pypiname}-${pkgver}"
+    python setup.py install --skip-build --root="${pkgdir}" --optimize=1
+    install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-gitdb() {
+    depends=('python2' 'python2-smmap>=2.0.0')
+
+    cd "${srcdir}/${_pypiname}-${pkgver}-py2"
+    python2 setup.py install --skip-build --root="${pkgdir}" --optimize=1
+    install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}