[arch-commits] Commit in python-gitpython/trunk (PKGBUILD)

[NicoHood]

    Date: Tuesday, June 13, 2017 @ 18:06:03
  Author: nicohood
Revision: 236668

upgpkg: python-gitpython 2.1.5-1

Modified:
  python-gitpython/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2017-06-13 18:05:16 UTC (rev 236667)
+++ PKGBUILD	2017-06-13 18:06:03 UTC (rev 236668)
@@ -0,0 +1,48 @@
+# Maintainer: NicoHood <archlinux {cat} nicohood {dog} de>
+# PGP ID: 97312D5EB9D7AE7D0BD4307351DAE9B7C1AE9161
+# Contributor: brent s. <bts[at]square-r00t[dot]net>
+
+_pkgname=python-gitpython
+_pypiname=GitPython
+pkgbase=python-gitpython
+pkgdesc="A python library used to interact with Git repositories"
+pkgname=('python-gitpython' 'python2-gitpython')
+pkgver=2.1.5
+pkgrel=1
+url="https://github.com/gitpython-developers/gitpython"
+license=('BSD')
+arch=("any")
+makedepends=('python' 'python-setuptools' 'python2' 'python2-setuptools')
+source=("${_pkgname}-${pkgver}.tar.gz::https://pypi.org/packages/source/G/${_pypiname}/${_pypiname}-${pkgver}.tar.gz"
+        "${_pkgname}-${pkgver}.tar.gz.asc::https://pypi.org/packages/source/G/${_pypiname}/${_pypiname}-${pkgver}.tar.gz.asc")
+sha512sums=('40350434edb12d3335ea6a9f0176df4eff0564c8c8388f6a9769d2ab9e46c708625849a079eaf4e1c5aa9eaf10d91f439097277d67e3c6b5e9659a88bfcdd4e2'
+            'SKIP')
+validpgpkeys=('4477ADC5977D7C60D2A7E3789FEE1C6A3B07188F') # Sebastian Thiel (In Rust I trust!) <byronimo at gmail.com>
+
+prepare() {
+    cp -a "${srcdir}/${_pypiname}-${pkgver}"{,-py2}
+}
+
+build() {
+    cd "${srcdir}/${_pypiname}-${pkgver}"
+    python setup.py build
+
+    cd "${srcdir}/${_pypiname}-${pkgver}-py2"
+    python2 setup.py build
+}
+
+package_python-gitpython() {
+    depends=('python' 'python-gitdb>=2.0.0')
+
+    cd "${srcdir}/${_pypiname}-${pkgver}"
+    python setup.py install --skip-build --root="${pkgdir}" --optimize=1
+    install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-gitpython() {
+    depends=('python2' 'python2-gitdb>=2.0.0')
+
+    cd "${srcdir}/${_pypiname}-${pkgver}-py2"
+    python2 setup.py install --skip-build --root="${pkgdir}" --optimize=1
+    install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}