[arch-commits] Commit in (4 files)

[Jelle van der Waa]

    Date: Friday, June 16, 2017 @ 19:18:45
  Author: jelle
Revision: 237814

initial commit

dependency of Calibre

Added:
  python-dukpy/
  python-dukpy/repos/
  python-dukpy/trunk/
  python-dukpy/trunk/PKGBUILD

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Added: python-dukpy/trunk/PKGBUILD
===================================================================
--- python-dukpy/trunk/PKGBUILD	                        (rev 0)
+++ python-dukpy/trunk/PKGBUILD	2017-06-16 19:18:45 UTC (rev 237814)
@@ -0,0 +1,39 @@
+# Maintainer: Jelle van der Waa <jelle at archlinux.org>
+# Contributor: Eli Schwartz <eschwartz93 at gmail.com>
+
+pkgbase='python-dukpy'
+pkgname=('python-dukpy' 'python2-dukpy')
+pkgver=0.3
+pkgrel=2
+pkgdesc="Python bindings for the duktape embeddable JavaScript engine"
+arch=('i686' 'x86_64')
+url="https://github.com/kovidgoyal/dukpy"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("dukpy-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
+sha256sums=('cc78c39ebba51f381c623b164cfb7dcf3caddf515fe7094bc53b7eca5d4e435e')
+
+build() {
+  cd "${srcdir}/dukpy-${pkgver}"
+
+  python setup.py build
+  python2 setup.py build
+}
+
+package_python-dukpy() {
+  depends=('python')
+
+  cd "${srcdir}/dukpy-${pkgver}"
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+
+  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/python-dukpy/LICENSE.txt"
+}
+
+package_python2-dukpy() {
+  depends=('python2')
+
+  cd "${srcdir}/dukpy-${pkgver}"
+  python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+
+  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/python2-dukpy/LICENSE.txt"
+}


Property changes on: python-dukpy/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property