[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Tuesday, June 20, 2017 @ 16:58:42
  Author: felixonmars
Revision: 239087

addpkg: haskell-wai-handler-launch 3.0.2.2-1

Added:
  haskell-wai-handler-launch/
  haskell-wai-handler-launch/repos/
  haskell-wai-handler-launch/trunk/
  haskell-wai-handler-launch/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: haskell-wai-handler-launch/trunk/PKGBUILD
===================================================================
--- haskell-wai-handler-launch/trunk/PKGBUILD	                        (rev 0)
+++ haskell-wai-handler-launch/trunk/PKGBUILD	2017-06-20 16:58:42 UTC (rev 239087)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=wai-handler-launch
+pkgname=haskell-wai-handler-launch
+pkgver=3.0.2.2
+pkgrel=1
+pkgdesc="Launch a web app in the default browser."
+url="http://github.com/yesodweb/wai"
+license=("MIT")
+arch=('i686' 'x86_64')
+depends=("ghc" "haskell-blaze-builder" "haskell-wai" "haskell-warp" "haskell-http-types"
+         "haskell-streaming-commons" "haskell-async")
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha256sums=('9c94c4da533ebcbbd28cf3dfbeb44a5e953dbf73b53cab0179f16931fa102908')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup haddock --hoogle --html
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    install -d -m755 "${pkgdir}/usr/share/doc/ghc/html/libraries"
+    ln -s "/usr/share/doc/${pkgname}/html" "${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+
+    # Remove static libs
+    find "$pkgdir"/usr/lib -name "*.a" -delete
+}


Property changes on: haskell-wai-handler-launch/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property