[arch-commits] Commit in (4 files)
Felix Yan
felixonmars at archlinux.org
Wed Jun 21 16:38:02 UTC 2017
Date: Wednesday, June 21, 2017 @ 16:38:01
Author: felixonmars
Revision: 239283
addpkg: hledger-ui 1.2-1
Added:
hledger-ui/
hledger-ui/repos/
hledger-ui/trunk/
hledger-ui/trunk/PKGBUILD
----------+
PKGBUILD | 40 ++++++++++++++++++++++++++++++++++++++++
1 file changed, 40 insertions(+)
Added: hledger-ui/trunk/PKGBUILD
===================================================================
--- hledger-ui/trunk/PKGBUILD (rev 0)
+++ hledger-ui/trunk/PKGBUILD 2017-06-21 16:38:01 UTC (rev 239283)
@@ -0,0 +1,40 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hledger-ui
+pkgver=1.2
+pkgrel=1
+pkgdesc="Curses-style user interface for the hledger accounting tool"
+url="http://hledger.org"
+license=("GPL")
+arch=('i686' 'x86_64')
+depends=('ghc' 'hledger' "haskell-hledger-lib" "haskell-ansi-terminal" "haskell-async"
+ "haskell-base-compat" "haskell-cmdargs" "haskell-data-default" "haskell-fsnotify"
+ "haskell-hunit" "haskell-microlens" "haskell-microlens-platform" "haskell-megaparsec"
+ "haskell-pretty-show" "haskell-safe" "haskell-split" "haskell-text" "haskell-text-zipper"
+ "haskell-vector" "haskell-brick" "haskell-vty")
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('07f571a66e94a34a20cd6145196cd3333137a6281c33c5f917facc3c70d424b01c0f2a3d4d0d0c543b877338a350b5add4d3a5d48bbe28009d5cc42a2c3d3e29')
+
+prepare() {
+ # It does nothing
+ sed -e '/mtl-compat/d' \
+ -e 's/megaparsec >=5.0 && < 5.3/megaparsec >=5.0 \&\& < 5.4/' \
+ -e 's/brick >= 0.12 && < 0.18/brick >= 0.12 \&\& < 0.19/' \
+ -i ${pkgname}-${pkgver}/${pkgname}.cabal
+}
+
+build() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+ runhaskell Setup configure -O --enable-executable-dynamic \
+ --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+ -f-oldtime -fthreaded
+ runhaskell Setup build
+}
+
+package() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+ runhaskell Setup copy --destdir="${pkgdir}"
+ rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}
Property changes on: hledger-ui/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list