[arch-commits] Commit in (4 files)

[Bruno Pagani]

    Date: Tuesday, June 27, 2017 @ 10:19:08
  Author: archange
Revision: 241151

Initial import (and unification) of python{,2}-netcdf4 from the AUR

Added:
  python-netcdf4/
  python-netcdf4/repos/
  python-netcdf4/trunk/
  python-netcdf4/trunk/PKGBUILD

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Added: python-netcdf4/trunk/PKGBUILD
===================================================================
--- python-netcdf4/trunk/PKGBUILD	                        (rev 0)
+++ python-netcdf4/trunk/PKGBUILD	2017-06-27 10:19:08 UTC (rev 241151)
@@ -0,0 +1,58 @@
+# Maintainer: Bruno Pagani (a.k.a. ArchangeGabriel) <archange at archlinux.org>
+# Contributor: Spyros Stathopoulos <foucault.online at gmail.com>
+# Contributor: richli <rich at dranek dot com>
+# Contributor: rememberthemer <rememberthemer at _GMAIL_DOT_COM_>
+
+_pkg=netCDF4
+pkgbase=python-${_pkg,,}
+pkgname=("python-${_pkg,,}" "python2-${_pkg,,}")
+pkgver=1.2.9
+pkgrel=1
+pkgdesc="Python/NumPy interface to the netCDF C library"
+arch=('x86_64' 'i686')
+url="https://unidata.github.io/${_pkg,,}-python"
+license=('MIT')
+makedepends=('cython' 'python-setuptools' 'cython2' 'python2-setuptools' 'python-numpy' 'python2-numpy' 'netcdf')
+source=("https://pypi.io/packages/source/n/${_pkg}/${_pkg}-${pkgver}.tar.gz")
+sha256sums=('259edab1f03b1c1b93bdbaa804d50211a0c9d8a15eee4f23988b5685c6c0d2c0')
+
+prepare() {
+    cp -a ${_pkg}-${pkgver}{,-py2}
+}
+
+build() {
+    cd ${_pkg}-${pkgver}
+    USE_NCCONFIG=1 python setup.py build
+
+    cd ../${_pkg}-${pkgver}-py2
+    USE_NCCONFIG=1 python2 setup.py build
+}
+
+check() {
+    cd ${_pkg}-${pkgver}/test
+    NO_NET=1 PYTHONPATH="../build/lib.linux-${CARCH}-3.6" python -B ./run_all.py || warning "Tests failed"
+
+    cd ../../${_pkg}-${pkgver}-py2/test
+    PYTHONPATH="../build/lib.linux-${CARCH}-2.7" python2 -B ./run_all.py || warning "Tests failed"
+}
+
+package_python-netcdf4() {
+    depends=('python-numpy' 'netcdf')
+
+    cd ${_pkg}-${pkgver}
+    USE_NCCONFIG=1 python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=2
+
+    rm -r "${pkgdir}"/usr/bin
+    install -Dm644 docs/netCDF4/* -t "${pkgdir}"/usr/share/doc/${pkgname}/docs/netCDF4
+    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
+
+package_python2-netcdf4() {
+    depends=('python2-numpy' 'netcdf')
+
+    cd ${_pkg}-${pkgver}-py2
+    USE_NCCONFIG=1 python2 setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=2
+
+    install -Dm644 docs/netCDF4/* -t "${pkgdir}"/usr/share/doc/${pkgname}/docs/netCDF4
+    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}