[arch-commits] Commit in gmime/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Christian Hesse
eworm at archlinux.org
Thu Mar 9 15:38:54 UTC 2017
Date: Thursday, March 9, 2017 @ 15:38:53
Author: eworm
Revision: 290215
archrelease: copy trunk to testing-x86_64
Added:
gmime/repos/testing-x86_64/
gmime/repos/testing-x86_64/PKGBUILD
(from rev 290214, gmime/trunk/PKGBUILD)
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Copied: gmime/repos/testing-x86_64/PKGBUILD (from rev 290214, gmime/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2017-03-09 15:38:53 UTC (rev 290215)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: Ben <ben at benmazer.net>
+
+pkgname=gmime
+pkgver=2.6.23
+pkgrel=2
+pkgdesc="Glorious MIME Utility Library"
+arch=(i686 x86_64)
+license=(GPL)
+url="http://spruce.sourceforge.net/gmime/"
+depends=(glib2 gpgme zlib)
+makedepends=(gtk-sharp-2 gobject-introspection gtk-doc git vala docbook-utils)
+_commit=2e404fd8aad343aff427df02680c0c1ca39c1cfe # master
+source=("git+https://git.gnome.org/browse/gmime#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ # Fixup tags for pkgver()
+ git tag -f 2.6.23 2e404fd8aad343aff427df02680c0c1ca39c1cfe
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ # get rid of that .wapi errors in fakeroot
+ export MONO_SHARED_DIR="$srcdir/weird"
+ mkdir -p "$MONO_SHARED_DIR"
+
+ cd "$pkgname"
+
+ ./configure --prefix=/usr \
+ --program-prefix=$pkgname \
+ --enable-gtk-doc \
+ --enable-mono \
+ --enable-smime \
+ --disable-static
+
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+ make
+}
+
+package() {
+ cd "$pkgname"
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list