[arch-commits] Commit in (4 files)
Felix Yan
felixonmars at archlinux.org
Fri Mar 10 05:39:12 UTC 2017
Date: Friday, March 10, 2017 @ 05:39:11
Author: felixonmars
Revision: 290454
addpkg: python-asn1crypto 0.21.1-1
Added:
python-asn1crypto/
python-asn1crypto/repos/
python-asn1crypto/trunk/
python-asn1crypto/trunk/PKGBUILD
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Added: python-asn1crypto/trunk/PKGBUILD
===================================================================
--- python-asn1crypto/trunk/PKGBUILD (rev 0)
+++ python-asn1crypto/trunk/PKGBUILD 2017-03-10 05:39:11 UTC (rev 290454)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Massimiliano Torromeo < massimiliano DOT torromeo AT gmail DOT com >
+
+pkgbase=python-asn1crypto
+pkgname=('python-asn1crypto' 'python2-asn1crypto')
+pkgver=0.21.1
+pkgrel=1
+arch=('any')
+license=('MIT')
+pkgdesc="Python ASN.1 library with a focus on performance and a pythonic API"
+url="https://github.com/wbond/asn1crypto"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+source=("git+https://github.com/wbond/asn1crypto.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+ cp -a asn1crypto{,-py2}
+}
+
+build() {
+ cd "$srcdir"/asn1crypto
+ python setup.py build
+
+ cd "$srcdir"/asn1crypto-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/asn1crypto
+ python run.py tests
+
+ cd "$srcdir"/asn1crypto-py2
+ python2 run.py tests
+}
+
+package_python-asn1crypto() {
+ depends=('python')
+
+ cd asn1crypto
+ python setup.py install --root="$pkgdir" --optimize=1
+ install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/python-asn1crypto/LICENSE
+}
+
+package_python2-asn1crypto() {
+ depends=('python2')
+
+ cd asn1crypto-py2
+ python2 setup.py install --root="$pkgdir" --optimize=1
+ install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/python2-asn1crypto/LICENSE
+}
Property changes on: python-asn1crypto/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list