[arch-commits] Commit in (4 files)
Timothy Redaelli
tredaelli at archlinux.org
Tue Mar 14 10:17:12 UTC 2017
Date: Tuesday, March 14, 2017 @ 10:17:10
Author: tredaelli
Revision: 216210
New split package: python-pyaes, python2-pyaes
Added:
python-pyaes/
python-pyaes/repos/
python-pyaes/trunk/
python-pyaes/trunk/PKGBUILD
----------+
PKGBUILD | 46 ++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 46 insertions(+)
Added: python-pyaes/trunk/PKGBUILD
===================================================================
--- python-pyaes/trunk/PKGBUILD (rev 0)
+++ python-pyaes/trunk/PKGBUILD 2017-03-14 10:17:10 UTC (rev 216210)
@@ -0,0 +1,46 @@
+# $Id$
+# Maintainer: Timothy Redaelli <timothy.redaelli at gmail.com>
+# Contributor: Andy Weidenbaum <archbaum at gmail.com>
+
+pkgbase=python-pyaes
+pkgname=('python-pyaes' 'python2-pyaes')
+_pipname=pyaes
+pkgver=1.6.0
+pkgrel=1
+pkgdesc="Pure-Python Implementation of the AES block-cipher and common modes of operation"
+arch=('any')
+makedepends=('python2-setuptools' 'python-setuptools')
+url="https://github.com/ricmoo/pyaes"
+license=('MIT')
+source=(https://pypi.org/packages/source/${_pipname:0:1}/$_pipname/$_pipname-$pkgver.tar.gz)
+sha256sums=('9cd5a54d914b1eebfb14fcb490315214b6a0304d9f1bb47e90d1d8e0b15ce92e')
+
+
+prepare() {
+ cp -R $_pipname-$pkgver python2-$_pipname-$pkgver
+}
+
+build() {
+ cd "$_pipname-$pkgver"
+ python setup.py build
+
+ cd "../python2-$_pipname-$pkgver"
+ python2 setup.py build
+}
+
+
+package_python-pyaes() {
+ depends=('python')
+ cd $_pipname-$pkgver
+ python setup.py install --root="$pkgdir/" --optimize=1
+
+ install -D -m644 LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.txt
+}
+
+package_python2-pyaes() {
+ depends=('python2')
+ cd "python2-$_pipname-$pkgver"
+ python2 setup.py install --root="$pkgdir" --optimize=1
+
+ install -D -m644 LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.txt
+}
Property changes on: python-pyaes/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list