[arch-commits] Commit in python-pycurl/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Wednesday, March 22, 2017 @ 05:36:48
  Author: felixonmars
Revision: 291199

archrelease: copy trunk to staging-x86_64

Added:
  python-pycurl/repos/staging-x86_64/
  python-pycurl/repos/staging-x86_64/PKGBUILD
    (from rev 291198, python-pycurl/trunk/PKGBUILD)

----------+
 PKGBUILD |   72 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)

Copied: python-pycurl/repos/staging-x86_64/PKGBUILD (from rev 291198, python-pycurl/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2017-03-22 05:36:48 UTC (rev 291199)
@@ -0,0 +1,72 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve> 
+
+_pypiname=pycurl
+pkgbase=python-$_pypiname
+pkgname=('python-pycurl' 'python2-pycurl')
+pkgver=7.43.0
+pkgrel=3
+arch=('i686' 'x86_64')
+url="http://pycurl.sourceforge.net/"
+license=('LGPL' 'MIT')
+makedepends=('python' 'python2' 'curl' 'git')
+checkdepends=('python-bottle' 'python2-bottle' 'python-nose-show-skipped' 'python2-nose-show-skipped'
+              'vsftpd' 'python-flaky' 'python2-flaky' 'python-pyflakes' 'python2-pyflakes')
+source=("git+https://github.com/pycurl/pycurl.git#tag=REL_${pkgver//./_}")
+sha1sums=('SKIP')
+
+prepare() {
+  cp -a $_pypiname{,-py2}
+
+  cd "$srcdir/$_pypiname"
+  find . -name '*.py' -exec sed -i -e "s|#! /usr/bin/env python|#!/usr/bin/env python3|" {} +
+    sed -i 's/"share", "doc", PACKAGE/"share", "doc", "python-pycurl"/' setup.py
+  sed -e "s/nosetests/nosetests3/" -e "s/python/python3/" -i tests/run.sh
+
+  cd "$srcdir/$_pypiname-py2"
+  find . -name '*.py' -exec sed -i -e "s|#! /usr/bin/env python|#!/usr/bin/env python2|" {} +
+    sed -i 's/"share", "doc", PACKAGE/"share", "doc", "python2-pycurl"/' setup.py
+  sed -e "s/nosetests/nosetests2/" -e "s/python/python2/" -i tests/run.sh
+  sed -e "s/pyflakes/pyflakes-python2/" -i Makefile
+}
+
+build() {
+  cd "$srcdir/$_pypiname"
+  make
+  python3 setup.py build --with-ssl
+
+  cd "$srcdir/$_pypiname-py2"
+  make
+  python2 setup.py build --with-ssl
+}
+
+check() {
+  export PYCURL_VSFTPD_PATH=vsftpd
+  # We don't have HTTP2 enabled
+
+  cd "$srcdir/$_pypiname"
+  PYTHONPATH="$PWD/build/lib.linux-$CARCH-3.6:$PYTHONPATH" make test || warning "Tests failed"
+
+  cd "$srcdir/$_pypiname-py2"
+  PYTHONPATH="$PWD/build/lib.linux-$CARCH-2.7:$PYTHONPATH" make PYTHON=python2 NOSETESTS=nosetests2 test || warning "Tests failed"
+}
+
+package_python-pycurl() {
+  pkgdesc="A Python 3.x interface to libcurl"
+  depends=('python' 'curl')
+
+  cd $_pypiname
+  python setup.py install -O1 --root="${pkgdir}"
+  install -D -m644 COPYING-MIT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-pycurl() {
+  pkgdesc="A Python 2.x interface to libcurl"
+  depends=('python2' 'curl')
+
+  cd $_pypiname-py2
+  python2 setup.py install -O1 --root="${pkgdir}"
+  install -D -m644 COPYING-MIT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}