[arch-commits] Commit in okular/repos (2 files)

Antonio Rojas arojas at archlinux.org
Sat Mar 25 01:06:57 UTC 2017


    Date: Saturday, March 25, 2017 @ 01:06:56
  Author: arojas
Revision: 291404

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  okular/repos/kde-unstable-x86_64/
  okular/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 291403, okular/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: okular/repos/kde-unstable-x86_64/PKGBUILD (from rev 291403, okular/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2017-03-25 01:06:56 UTC (rev 291404)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=okular
+pkgver=17.03.80
+pkgrel=1
+pkgdesc='Document Viewer'
+arch=(i686 x86_64)
+url="https://kde.org/applications/graphics/okular/"
+license=(GPL LGPL FDL)
+groups=(kde-applications kdegraphics)
+depends=(djvulibre libspectre libkexiv2 poppler-qt5 qca-qt5 kpty kactivities threadweaver kjs kparts)
+makedepends=(extra-cmake-modules ebook-tools kdegraphics-mobipocket kdoctools khtml python chmlib)
+optdepends=('ebook-tools: mobi and epub support'
+            'kdegraphics-mobipocket: mobi support'
+            'khtml: CHM support' 'chmlib: CHM support')
+conflicts=(kdegraphics-okular)
+replaces=(kdegraphics-okular)
+source=("https://download.kde.org/stable/applications/${pkgver}/src/okular-${pkgver}.tar.xz"{,.sig})
+sha256sums=('e61f1becf0f4f500670cb37275aefae932ff1a462a32483c58606c52452687a2'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7) # Albert Astals Cid <aacid at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}


More information about the arch-commits mailing list