[arch-commits] Commit in (4 files)
Sven-Hendrik Haase
svenstaro at archlinux.org
Thu May 4 19:28:02 UTC 2017
Date: Thursday, May 4, 2017 @ 19:28:02
Author: svenstaro
Revision: 227041
Prepare tensorflow
Added:
tensorflow/
tensorflow/repos/
tensorflow/trunk/
tensorflow/trunk/PKGBUILD
----------+
PKGBUILD | 75 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 75 insertions(+)
Added: tensorflow/trunk/PKGBUILD
===================================================================
--- tensorflow/trunk/PKGBUILD (rev 0)
+++ tensorflow/trunk/PKGBUILD 2017-05-04 19:28:02 UTC (rev 227041)
@@ -0,0 +1,75 @@
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+# Contributor: Adria Arrufat (archdria) <adria.arrufat+AUR at protonmail.ch>
+# Contributor: Thibault Lorrain (fredszaq) <fredszaq at gmail.com>
+
+pkgbase=tensorflow
+pkgname=(tensorflow python-tensorflow)
+pkgver=1.1.0
+pkgrel=1
+pkgdesc="Library for computation using data flow graphs for scalable machine learning"
+url="https://www.tensorflow.org/"
+license=('Apache2')
+arch=('x86_64')
+provides=('tensorflow' 'libtensorflow')
+conflicts=('tensorflow' 'libtensorflow')
+makedepends=('git' 'bazel' 'python-numpy' 'gcc5' 'cuda' 'cudnn')
+optdepends=('cuda: GPU support'
+ 'cudnn: GPU support')
+source=("https://github.com/tensorflow/tensorflow/archive/v${pkgver}.tar.gz")
+sha512sums=('5dc0e13742c06cbc6407cc54de02d825928e9c16eeee169b198bbec95acd2a9af49bf3df092c99be1e3adadd40c5f4edf8735c6ad67a370c90c1e74146c32eac')
+
+prepare() {
+ cd tensorflow-${pkgver}
+ # setup environment variables
+ export PYTHON_BIN_PATH=/usr/bin/python
+ export USE_DEFAULT_PYTHON_LIB_PATH=1
+ export CC_OPT_FLAGS="-march=x86-64"
+ export TF_NEED_JEMALLOC=1
+ export TF_NEED_GCP=0
+ export TF_NEED_HDFS=0
+ export TF_ENABLE_XLA=1
+ export TF_NEED_VERBS=0
+ export TF_NEED_OPENCL=0
+ export TF_NEED_CUDA=1
+ export GCC_HOST_COMPILER_PATH=/usr/bin/gcc-5
+
+ # For next version instead of the gcc-5 stuff:
+ # export TF_CUDA_CLANG=1
+ # export CLANG_CUDA_COMPILER_PATH=/usr/bin/clang
+
+ export CUDA_TOOLKIT_PATH=/opt/cuda
+ export TF_CUDA_VERSION=$($CUDA_TOOLKIT_PATH/bin/nvcc --version | sed -n 's/^.*release \(.*\),.*/\1/p')
+ export CUDNN_INSTALL_PATH=/opt/cuda
+ export TF_CUDNN_VERSION=$(sed -n 's/^#define CUDNN_MAJOR\s*\(.*\).*/\1/p' $CUDNN_INSTALL_PATH/include/cudnn.h)
+ export TF_CUDA_COMPUTE_CAPABILITIES=3.5,5.2,6.1
+}
+
+build() {
+ cd tensorflow-${pkgver}
+
+ ./configure
+ bazel build --config=opt --config=cuda //tensorflow:libtensorflow.so
+ bazel build --config=opt --config=cuda //tensorflow/tools/pip_package:build_pip_package
+ bazel-bin/tensorflow/tools/pip_package/build_pip_package ${srcdir}/tmp
+}
+
+package_tensorflow() {
+ cd tensorflow-${pkgver}
+
+ install -Dm755 bazel-bin/tensorflow/libtensorflow.so ${pkgdir}/usr/lib/lib${pkgname}.so
+ install -Dm644 tensorflow/c/c_api.h ${pkgdir}/usr/include/${pkgname}/c_api.h
+ install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+}
+
+package_python-tensorflow() {
+ cd tensorflow-${pkgver}
+
+ WHEEL_PACKAGE=`find $srcdir/tmp -name "tensor*.whl"`
+ pip install --ignore-installed --upgrade --root $pkgdir/ $WHEEL_PACKAGE --no-dependencies
+ find ${pkgdir} -name __pycache__ -exec rm -r {} +
+
+ pip install ${srcdir}/tmp/tensorflow-${pkgver}-py2-none-any.whl
+ install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list