[arch-commits] Commit in (4 files)
Giancarlo Razzolini
grazzolini at archlinux.org
Tue May 16 14:55:32 UTC 2017
Date: Tuesday, May 16, 2017 @ 14:55:31
Author: grazzolini
Revision: 228249
addpkg: xf86-video-qxl
Added:
xf86-video-qxl/
xf86-video-qxl/repos/
xf86-video-qxl/trunk/
xf86-video-qxl/trunk/PKGBUILD
----------+
PKGBUILD | 51 +++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 51 insertions(+)
Added: xf86-video-qxl/trunk/PKGBUILD
===================================================================
--- xf86-video-qxl/trunk/PKGBUILD (rev 0)
+++ xf86-video-qxl/trunk/PKGBUILD 2017-05-16 14:55:31 UTC (rev 228249)
@@ -0,0 +1,51 @@
+# Maintainer: Giancarlo Razzolini <grazzolini at archlinux.org>
+# Contributor: Christian Hesse <mail at eworm.de>
+# Contributor: Yonathan Dossow
+# Contributor: Ansgar Taflinski <ataflinski at uni-koblenz.de>
+
+pkgname=xf86-video-qxl
+pkgver=0.1.5
+pkgrel=2
+pkgdesc='Xorg X11 qxl video driver'
+arch=('x86_64' 'i686')
+url='http://www.x.org'
+license=('MIT')
+groups=('xorg-drivers')
+depends=('spice')
+optdepends=('python2: for Xspice')
+makedepends=('xorg-server-devel' 'X-ABI-VIDEODRV_VERSION=23' 'spice-protocol'
+ 'xf86dgaproto' 'xproto' 'fontsproto' 'randrproto' 'renderproto'
+ 'videoproto' 'resourceproto' 'scrnsaverproto' 'git')
+conflicts=('xf86-video-qxl-git' 'X-ABI-VIDEODRV_VERSION<23' 'X-ABI-VIDEODRV_VERSION>=24')
+validpgpkeys=('94A9F75661F77A6168649B23A9D8C21429AC6C82')
+source=("https://xorg.freedesktop.org/releases/individual/driver/${pkgname}-${pkgver}.tar.bz2"{,.sig})
+sha256sums=('b18682e04503c6326f7bf7190f3ee50a3d4d69758a2a3cc9af102a6b3f114c92'
+ 'SKIP')
+sha512sums=('7510b2d037b3e978df6063b29e2406f3d1270695a239f29fdaec9b1dc65a30ab10cb959f15eb336f78e93aa708d41c64c5ea43803958feffc64542229605b782'
+ 'SKIP')
+
+prepare() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+
+ # this is python 2.x
+ sed -i '1c #!/usr/bin/python2' scripts/Xspice
+}
+
+build() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+
+ autoreconf -fi
+ ./configure \
+ --enable-xspice \
+ --prefix=/usr
+ make
+}
+
+package() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+
+ make DESTDIR="${pkgdir}/" install
+
+ install -v -D -m0755 scripts/Xspice "${pkgdir}"/usr/bin/Xspice
+}
+
Property changes on: xf86-video-qxl/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list