[arch-commits] Commit in (5 files)

[Bartłomiej Piotrowski]

    Date: Wednesday, May 31, 2017 @ 13:06:55
  Author: bpiotrowski
Revision: 231562

extra2community: Moving hdf5-openmpi from extra to community

Added:
  hdf5-openmpi/
  hdf5-openmpi/repos/
  hdf5-openmpi/trunk/
  hdf5-openmpi/trunk/PKGBUILD
  hdf5-openmpi/trunk/mpi.patch

-----------+
 PKGBUILD  |   67 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 mpi.patch |   18 ++++++++++++++++
 2 files changed, 85 insertions(+)

Added: hdf5-openmpi/trunk/PKGBUILD
===================================================================
--- hdf5-openmpi/trunk/PKGBUILD	                        (rev 0)
+++ hdf5-openmpi/trunk/PKGBUILD	2017-05-31 13:06:55 UTC (rev 231562)
@@ -0,0 +1,67 @@
+# $Id$
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Contributor: Stefan Husmann <stefan-husmann at t-online.de>
+# Contributor: damir <damir at archlinux.org>
+# Contributor: Tom K <tomk at runbox.com>
+# Contributor: Jed Brown <jed at 59A2.org>
+# Contributor: Simone Pezzuto <junki.gnu at gmail.com>
+
+pkgname=hdf5-openmpi
+_pkgname=hdf5
+pkgver=1.10.0_patch1
+_pkgver=1.10.0-patch1
+pkgrel=1
+arch=('i686' 'x86_64')
+pkgdesc="General purpose library and file format for storing scientific data (OpenMPI version)"
+url="http://www.hdfgroup.org/HDF5/"
+license=('custom')
+depends=('zlib' 'sh' 'openmpi')
+makedepends=('time')
+provides=('hdf5')
+conflicts=('hdf5')
+source=(ftp://ftp.hdfgroup.org/HDF5/releases/${_pkgname}-1.10/${_pkgname}-${_pkgver}/src/${_pkgname}-${_pkgver}.tar.bz2
+        mpi.patch)
+sha1sums=('2f34251186fa9e59887d8f094bc0bc90187d0aa4'
+          '658d4a3e537c9c76da3200effa8f95b656a21936')
+
+build() {
+  cd "$srcdir/${_pkgname}-${pkgver/_/-}"
+
+  # FS#33343
+  patch -Np1 -i "${srcdir}/mpi.patch"
+
+  ./configure \
+    CXX="mpicxx" \
+    CC="mpicc" \
+    FC="mpif90" \
+    F9X="mpif90" \
+    RUNPARALLEL="mpirun" \
+    OMPI_MCA_disable_memory_allocator=1 \
+    --prefix=/usr \
+    --with-pthread=/usr/lib/ \
+    --enable-linux-lfs \
+    --enable-unsupported \
+    --enable-shared \
+    --disable-static \
+    --enable-build-mode=production \
+    --with-zlib \
+    --enable-parallel=yes \
+    --enable-cxx \
+    --disable-sharedlib-rpath
+
+  make
+}
+
+package() {
+  cd "$srcdir/${_pkgname}-${pkgver/_/-}"
+
+  make -j1 DESTDIR="${pkgdir}" install
+
+  install -d -m755 "$pkgdir/usr/share/$_pkgname"
+  mv "$pkgdir"/usr/share/{hdf5_examples,$_pkgname/examples}
+
+  install -d -m755 "$pkgdir/usr/share/licenses/${pkgname}"
+  install -m644 "$srcdir/${_pkgname}-${pkgver/_/-}/COPYING" \
+          "$pkgdir/usr/share/licenses/${pkgname}/LICENSE" 
+}
+


Property changes on: hdf5-openmpi/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: hdf5-openmpi/trunk/mpi.patch
===================================================================
--- hdf5-openmpi/trunk/mpi.patch	                        (rev 0)
+++ hdf5-openmpi/trunk/mpi.patch	2017-05-31 13:06:55 UTC (rev 231562)
@@ -0,0 +1,18 @@
+Prevent accidental inclusion of mpi c++ headers 
+when hdf5.h is included third party library
+
+https://bugs.gentoo.org/show_bug.cgi?id=420777
+https://bugs.archlinux.org/task/33343
+
+--- a/src/H5public.h
++++ b/src/H5public.h
+@@ -58,6 +58,8 @@
+ #   include <stddef.h>
+ #endif
+ #ifdef H5_HAVE_PARALLEL
++#   define OMPI_SKIP_MPICXX   /* Make sure that cxx specific headers are not included */
++#   define MPICH_SKIP_MPICXX
+ #   include <mpi.h>
+ #ifndef MPI_FILE_NULL		/*MPIO may be defined in mpi.h already       */
+ #   include <mpio.h>
+