[arch-commits] Commit in (3 files)

[Antonio Rojas]

    Date: Friday, November 3, 2017 @ 23:49:22
  Author: arojas
Revision: 265383

New electum dependency

Added:
  python-jsonrpclib-pelix/
  python-jsonrpclib-pelix/trunk/
  python-jsonrpclib-pelix/trunk/PKGBUILD

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Added: python-jsonrpclib-pelix/trunk/PKGBUILD
===================================================================
--- python-jsonrpclib-pelix/trunk/PKGBUILD	                        (rev 0)
+++ python-jsonrpclib-pelix/trunk/PKGBUILD	2017-11-03 23:49:22 UTC (rev 265383)
@@ -0,0 +1,43 @@
+# Maintainer:
+# Contributor: Andy Weidenbaum <archbaum at gmail.com>
+
+pkgbase=python-jsonrpclib-pelix
+pkgname=(python-jsonrpclib-pelix python2-jsonrpclib-pelix)
+pkgver=0.3.1
+pkgrel=2
+pkgdesc="A Python JSON-RPC over HTTP that mirrors xmlrpclib syntax"
+arch=(any)
+makedepends=(python-setuptools python2-setuptools)
+url="https://github.com/tcalmant/jsonrpclib"
+license=('Apache')
+source=(https://pypi.io/packages/source/j/jsonrpclib-pelix/jsonrpclib-pelix-$pkgver.tar.gz)
+sha256sums=('5417b1508d5a50ec64f6e5b88907f111155d52607b218ff3ba9a777afb2e49e3')
+
+prepare() {
+  cp -r jsonrpclib-pelix-$pkgver jsonrpclib-pelix-$pkgver-py2
+  cd jsonrpclib-pelix-$pkgver-py2
+  find -name '*.py' | xargs sed -e 's|/usr/bin/python|/usr/bin/python2|' -e 's|/usr/bin/env python|/usr/bin/env python2|' -i
+}
+
+build() {
+  cd jsonrpclib-pelix-$pkgver
+  python setup.py build
+
+  cd ../jsonrpclib-pelix-$pkgver-py2
+  python2 setup.py build
+}
+
+package_python-jsonrpclib-pelix() {
+  depends=(python)
+  conflicts=(python-jsonrpclib)
+  cd jsonrpclib-pelix-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-jsonrpclib-pelix() {
+  depends=(python2)
+  conflicts=(python2-jsonrpclib)
+  cd jsonrpclib-pelix-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}
+