[arch-commits] Commit in docker-compose/repos (2 files)

[Felix Yan]

    Date: Thursday, November 9, 2017 @ 09:17:09
  Author: felixonmars
Revision: 265839

archrelease: copy trunk to community-testing-x86_64

Added:
  docker-compose/repos/community-testing-x86_64/
  docker-compose/repos/community-testing-x86_64/PKGBUILD
    (from rev 265838, docker-compose/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: docker-compose/repos/community-testing-x86_64/PKGBUILD (from rev 265838, docker-compose/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2017-11-09 09:17:09 UTC (rev 265839)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Iwan Timmer <irtimmer at gmail.com>
+# Contributor: Vincent Demeester <vincent at sbr.io>
+# Contributor: Josh VanderLinden <arch at cloudlery.com>
+
+pkgname=docker-compose
+pkgver=1.17.1
+pkgrel=1
+pkgdesc="Fast, isolated development environments using Docker"
+arch=('x86_64')
+url="https://www.docker.com/"
+license=("Apache")
+depends=('python-cached-property' 'python-docopt' 'python-yaml' 'python-requests'
+         'python-texttable' 'python-websocket-client' 'python-docker' 'python-dockerpty'
+         'python-six' 'python-jsonschema' 'python-setuptools')
+depends_x86_64+=('docker')
+checkdepends=('python-pytest-runner' 'python-mock')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/docker/compose/archive/$pkgver.tar.gz")
+sha512sums=('20fba4b7049f9b699b3eba571ca242a1fa928f7a326141cdbb45a45419d67ed243f48ee994ab0ec503a92d39b420035c0f1580b562ce70f756d24bd61d5102c1')
+
+prepare() {
+  cd compose-$pkgver
+
+  # Remove upper bound on requires
+  sed -i 's/==/>=/g' requirements.txt
+  sed -i "s/, < .*',$/',/" setup.py
+}
+
+build() {
+  cd compose-$pkgver
+  python setup.py build
+}
+
+check() {
+  # Hack entry points by installing it
+  # TODO: need a running docker daemon to test
+
+  cd compose-$pkgver
+  python setup.py install --root="$PWD/tmp_install" --optimize=1
+  # PATH="$PWD/tmp_install/usr/bin:$PATH" PYTHONPATH="$PWD/tmp_install/usr/lib/python3.6/site-packages:$PYTHONPATH" python setup.py pytest
+}
+
+package() {
+  cd compose-$pkgver
+
+  python setup.py install -O1 --root="$pkgdir"
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  install -Dm644 contrib/completion/bash/docker-compose "$pkgdir"/usr/share/bash-completion/completions/docker-compose
+}