[arch-commits] Commit in pandoc/repos (2 files)

[Felix Yan]

    Date: Thursday, November 9, 2017 @ 09:40:49
  Author: felixonmars
Revision: 265877

archrelease: copy trunk to community-staging-x86_64

Added:
  pandoc/repos/community-staging-x86_64/
  pandoc/repos/community-staging-x86_64/PKGBUILD
    (from rev 265876, pandoc/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: pandoc/repos/community-staging-x86_64/PKGBUILD (from rev 265876, pandoc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2017-11-09 09:40:49 UTC (rev 265877)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=pandoc
+pkgver=2.0.1.1
+pkgrel=2
+pkgdesc="Conversion between markup formats"
+url="http://pandoc.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-http" "haskell-juicypixels" "haskell-sha" "haskell-aeson"
+         "haskell-aeson-pretty" "haskell-base64-bytestring" "haskell-blaze-html"
+         "haskell-blaze-markup" "haskell-case-insensitive" "haskell-cmark-gfm"
+         "haskell-data-default" "haskell-doctemplates" "haskell-glob" "haskell-mtl"
+         "haskell-haddock-library" "haskell-skylighting" "haskell-hslua" "haskell-http-client"
+         "haskell-syb" "haskell-http-client-tls" "haskell-http-types" "haskell-safe" "haskell-split"
+         "haskell-text" "haskell-texmath" "haskell-network" "haskell-pandoc-types" "haskell-parsec"
+         "haskell-random" "haskell-scientific" "haskell-tagsoup" "haskell-temporary"
+         "haskell-network-uri" "haskell-unordered-containers" "haskell-zip-archive" "haskell-vector"
+         "haskell-xml" "haskell-yaml" "haskell-zlib")
+optdepends=('pandoc-citeproc: for citation rendering with pandoc-citeproc filter'
+            'pandoc-crossref: for numbering figures, equations, tables and cross-references to them with pandoc-crossref filter'
+            'texlive-core: for pdf output')
+conflicts=('haskell-pandoc')
+replaces=('haskell-pandoc')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('ff78a9c6570294f7ba37c1908f7698cf45afc7a2657f2ec861fcb1741d30b3e0a3a6b777c31563992096632f45c1c06861609275300e351b227086e36ec936ce')
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgbase}" --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-old-locale -fnetwork-uri -f-trypandoc -f-embed_data_files -f-weigh-pandoc -f-static
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${pkgbase}-${pkgver}"
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/COPYING.md"
+}