[arch-commits] Commit in haskell-cairo/repos (2 files)

Felix Yan felixonmars at archlinux.org
Fri Nov 10 04:14:06 UTC 2017


    Date: Friday, November 10, 2017 @ 04:14:00
  Author: felixonmars
Revision: 266089

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-cairo/repos/community-staging-x86_64/
  haskell-cairo/repos/community-staging-x86_64/PKGBUILD
    (from rev 266088, haskell-cairo/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: haskell-cairo/repos/community-staging-x86_64/PKGBUILD (from rev 266088, haskell-cairo/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2017-11-10 04:14:00 UTC (rev 266089)
@@ -0,0 +1,38 @@
+# $Id$
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+
+pkgname=haskell-cairo
+pkgver=0.13.4.1
+pkgrel=1
+pkgdesc="Binding to the cairo library for Gtk2Hs."
+url="https://hackage.haskell.org/package/cairo"
+license=('LGPL2.1')
+arch=('x86_64')
+depends=('ghc-libs' 'cairo' 'haskell-mtl' 'haskell-utf8-string' 'haskell-text')
+makedepends=("haskell-gtk2hs-buildtools" "mesa" 'ghc')
+conflicts=('gtk2hs-cairo')
+provides=('gtk2hs-cairo')
+replaces=('gtk2hs-cairo')
+source=("https://hackage.haskell.org/packages/archive/cairo/${pkgver}/cairo-${pkgver}.tar.gz")
+sha512sums=('d7570190ee637a637f8612ef3cc5e6a6ee7f093329180cac5f818e75119549a63ca99af7a0bfabd7445a9de1ae1c69dea0baa6620920ffd3dd92c7d062bc4d02')
+
+build() {
+    cd "${srcdir}/cairo-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/cairo-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+}


More information about the arch-commits mailing list