[arch-commits] Commit in gtk-doc/repos (testing-any testing-any/PKGBUILD)

[Evangelos Foutras]

    Date: Sunday, November 12, 2017 @ 10:50:55
  Author: foutrelis
Revision: 309588

archrelease: copy trunk to testing-any

Added:
  gtk-doc/repos/testing-any/
  gtk-doc/repos/testing-any/PKGBUILD
    (from rev 309587, gtk-doc/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: gtk-doc/repos/testing-any/PKGBUILD (from rev 309587, gtk-doc/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2017-11-12 10:50:55 UTC (rev 309588)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gtk-doc
+pkgver=1.26+23+g8ad03e1
+pkgrel=1
+pkgdesc="Documentation tool for public library API"
+url="https://www.gtk.org/gtk-doc/"
+arch=(any)
+license=(GPL FDL)
+depends=(docbook-xsl docbook-xml source-highlight glib2-docs python-six)
+makedepends=(dblatex git yelp-tools)
+checkdepends=(bc gtk3)
+optdepends=('dblatex: PDF support')
+_commit=8ad03e164f3091df68a9fed5492b54cd61d0ac51  # master
+source=("git+https://git.gnome.org/browse/gtk-doc#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed -e 's/GTK_DOC_//' -e 's/_/\./g' -e 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # Recover a file from the old version, because GStreamer/common needs it
+  git checkout 1db161bd708cdfb88b362ea0b5d047034d9c3272 -- gtkdoc-common.pl.in
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --disable-static
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  sed 's|@PERL@|/usr/bin/perl|g' gtkdoc-common.pl.in \
+    | install -D /dev/stdin "$pkgdir/usr/share/gtk-doc/data/gtkdoc-common.pl"
+}