[arch-commits] Commit in tracker/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Evangelos Foutras]

    Date: Sunday, November 12, 2017 @ 13:46:53
  Author: foutrelis
Revision: 309635

archrelease: copy trunk to staging-x86_64

Added:
  tracker/repos/staging-x86_64/
  tracker/repos/staging-x86_64/PKGBUILD
    (from rev 309634, tracker/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: tracker/repos/staging-x86_64/PKGBUILD (from rev 309634, tracker/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2017-11-12 13:46:53 UTC (rev 309635)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+
+pkgname=tracker
+pkgver=2.0.1
+pkgrel=2
+pkgdesc="Desktop-neutral user information store, search tool and indexer"
+url="https://wiki.gnome.org/Projects/Tracker"
+arch=(i686 x86_64)
+license=(GPL)
+depends=(sqlite icu glib2 libffi util-linux libstemmer libseccomp libsoup json-glib upower libnm)
+makedepends=(python2 gobject-introspection intltool vala git gtk-doc bash-completion)
+groups=(gnome)
+_commit=3096d13c3e47b4ff5d8ac0cfffcd19444556350e  # tags/2.0.1^0
+source=("git+https://git.gnome.org/browse/tracker#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib/$pkgname \
+    --enable-unit-tests \
+    --enable-functional-tests \
+    --enable-gtk-doc
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  # Some tests only work with the schemas installed
+  dbus-run-session make -k check || :
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  rm -r "$pkgdir/usr/share/tracker-tests"
+}