[arch-commits] Commit in tracker-miners/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Evangelos Foutras foutrelis at archlinux.org
Sun Nov 12 19:02:07 UTC 2017


    Date: Sunday, November 12, 2017 @ 19:02:02
  Author: foutrelis
Revision: 309663

archrelease: copy trunk to staging-x86_64

Added:
  tracker-miners/repos/staging-x86_64/
  tracker-miners/repos/staging-x86_64/PKGBUILD
    (from rev 309662, tracker-miners/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: tracker-miners/repos/staging-x86_64/PKGBUILD (from rev 309662, tracker-miners/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2017-11-12 19:02:02 UTC (rev 309663)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=tracker-miners
+pkgver=2.0.2
+pkgrel=2
+pkgdesc="Collection of data extractors for Tracker/Nepomuk"
+url="https://wiki.gnome.org/Projects/Tracker"
+arch=(i686 x86_64)
+license=(GPL)
+depends=(tracker gst-plugins-base-libs exempi flac libexif libcue libgrss libgsf libgxps
+         libiptcdata libosinfo libvorbis poppler-glib taglib totem-plparser giflib)
+makedepends=(intltool git python)
+groups=(gnome)
+_commit=470503644f003843ad031ee389b91b2228af2a09  # tags/2.0.2^0
+source=("git+https://git.gnome.org/browse/tracker-miners#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib/$pkgname \
+    --enable-unit-tests \
+    --enable-functional-tests \
+    --enable-libflac \
+    --enable-libvorbis \
+    --enable-guarantee-metadata
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  # Some tests only work with the schemas installed
+  dbus-run-session make -k check || :
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  rm -r "$pkgdir/usr/share/tracker-tests"
+}


More information about the arch-commits mailing list