[arch-commits] Commit in evolution-data-server/repos (2 files)

[Felix Yan]

    Date: Sunday, November 12, 2017 @ 19:11:02
  Author: felixonmars
Revision: 309671

archrelease: copy trunk to staging-x86_64

Added:
  evolution-data-server/repos/staging-x86_64/
  evolution-data-server/repos/staging-x86_64/PKGBUILD
    (from rev 309670, evolution-data-server/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: evolution-data-server/repos/staging-x86_64/PKGBUILD (from rev 309670, evolution-data-server/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2017-11-12 19:11:02 UTC (rev 309671)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=evolution-data-server
+pkgver=3.26.2.1
+pkgrel=2
+pkgdesc="Centralized access to appointments and contacts"
+url="https://wiki.gnome.org/Apps/Evolution"
+arch=(i686 x86_64)
+depends=(gnome-online-accounts nss krb5 libgweather libical db libgdata libphonenumber)
+makedepends=(intltool gperf gobject-introspection vala gtk-doc boost git cmake ninja)
+license=(GPL)
+_commit=7149f838ab4a908c1a8fc71fcac3a769b3043895  # tags/EVOLUTION_DATA_SERVER_3_26_2_1^0
+source=("git+https://git.gnome.org/browse/evolution-data-server#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^EVOLUTION_DATA_SERVER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  cd $pkgname
+
+  cmake . -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DLIBEXEC_INSTALL_DIR=/usr/lib/$pkgname \
+    -DSYSCONF_INSTALL_DIR=/etc \
+    -DENABLE_INTROSPECTION=ON \
+    -DENABLE_VALA_BINDINGS=ON \
+    -DENABLE_UOA=OFF \
+    -DENABLE_GOOGLE_AUTH=ON \
+    -DENABLE_GTK_DOC=ON \
+    -DWITH_PHONENUMBER=ON
+  ninja
+}
+
+check() {
+  cd $pkgname
+  # libedata-book tests fail because they try to
+  # mkdir /usr/lib/evolution-data-server/camel-providers
+  ninja test || :
+}
+
+package() {
+  cd $pkgname
+  DESTDIR="$pkgdir" ninja install
+}