[arch-commits] Commit in gjs/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Jan Steffens
heftig at archlinux.org
Thu Nov 16 15:04:32 UTC 2017
Date: Thursday, November 16, 2017 @ 15:04:31
Author: heftig
Revision: 310054
archrelease: copy trunk to testing-x86_64
Added:
gjs/repos/testing-x86_64/
gjs/repos/testing-x86_64/PKGBUILD
(from rev 310053, gjs/trunk/PKGBUILD)
----------+
PKGBUILD | 43 +++++++++++++++++++++++++++++++++++++++++++
1 file changed, 43 insertions(+)
Copied: gjs/repos/testing-x86_64/PKGBUILD (from rev 310053, gjs/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2017-11-16 15:04:31 UTC (rev 310054)
@@ -0,0 +1,43 @@
+# $Id$
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=gjs
+pkgver=1.50.2
+pkgrel=1
+pkgdesc="Javascript Bindings for GNOME"
+url="https://wiki.gnome.org/Projects/Gjs"
+arch=(x86_64)
+license=(GPL)
+depends=(cairo gobject-introspection-runtime js52 gtk3)
+makedepends=(gobject-introspection git autoconf-archive xorg-server-xvfb)
+checkdepends=(valgrind)
+_commit=9a97b89ac410091466961d8430ff4da399b83bbe # tags/1.50.2^0
+source=("git+https://gitlab.gnome.org/GNOME/gjs.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgname
+ ./configure --prefix=/usr --disable-static --libexecdir=/usr/lib --with-xvfb-tests
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+check() {
+ cd $pkgname
+ make check
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list