[arch-commits] Commit in k3b/repos (kde-unstable-x86_64 kde-unstable-x86_64/PKGBUILD)

Antonio Rojas arojas at archlinux.org
Fri Nov 17 18:37:41 UTC 2017


    Date: Friday, November 17, 2017 @ 18:37:41
  Author: arojas
Revision: 310233

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  k3b/repos/kde-unstable-x86_64/
  k3b/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 310232, k3b/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: k3b/repos/kde-unstable-x86_64/PKGBUILD (from rev 310232, k3b/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2017-11-17 18:37:41 UTC (rev 310233)
@@ -0,0 +1,47 @@
+# Maintainer: Eric Bélanger <eric at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgname=k3b
+pkgver=17.11.80
+pkgrel=1
+epoch=1
+pkgdesc="Feature-rich and easy to handle CD burning application"
+arch=(x86_64)
+url="https://userbase.kde.org/K3b"
+license=(GPL)
+depends=(libkcddb kcmutils knotifyconfig libmad kfilemetadata knewstuff
+         libmpcdec libdvdread libburn qt5-webkit)
+makedepends=(extra-cmake-modules kdoctools python)
+optdepends=('cdrtools: for CD burning with cdrecord'
+            'dvd+rw-tools: for DVD burning support'
+            'vcdimager: for VCD burning support'
+            'emovix: for bootable multimedia CD/DVD support'
+            'cdrdao: for disk-at-once (DAO) mode support'
+            'cdparanoia: for CD ripping support' 'transcode: for DVD ripping support')
+groups=(kde-applications kdemultimedia)
+source=("https://download.kde.org/unstable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('00aad9061684a1b94f3ecf4165a0587a946fa6b83dfe76afe9ec5d7b35784974'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DBUILD_TESTING=OFF \
+    -DK3B_ENABLE_PERMISSION_HELPER=ON
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}



More information about the arch-commits mailing list