[arch-commits] Commit in (libindi libindi/repos libindi/trunk libindi/trunk/PKGBUILD)
Antonio Rojas
arojas at archlinux.org
Mon Nov 20 09:27:10 UTC 2017
Date: Monday, November 20, 2017 @ 09:27:09
Author: arojas
Revision: 267526
extra2community: Moving libindi from extra to community
Added:
libindi/
libindi/repos/
libindi/trunk/
libindi/trunk/PKGBUILD
----------+
PKGBUILD | 38 ++++++++++++++++++++++++++++++++++++++
1 file changed, 38 insertions(+)
Added: libindi/trunk/PKGBUILD
===================================================================
--- libindi/trunk/PKGBUILD (rev 0)
+++ libindi/trunk/PKGBUILD 2017-11-20 09:27:09 UTC (rev 267526)
@@ -0,0 +1,38 @@
+# $Id$
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+
+pkgname=libindi
+pkgver=1.5.0
+pkgrel=1
+pkgdesc="A distributed control protocol designed to operate astronomical instrumentation"
+url="http://www.indilib.org/index.php?title=Main_Page"
+license=(GPL2)
+arch=(x86_64)
+depends=(libnova cfitsio libusb libjpeg gsl curl)
+makedepends=(cmake boost qt5-base)
+#source=("https://github.com/indilib/indi/releases/download/v$pkgver/libindi_$pkgver.tar.gz")
+source=($pkgname-$pkgver.tar.gz::"https://github.com/indilib/indi/archive/v$pkgver.tar.gz")
+sha256sums=('ec955968aea471c97e00b2476736b0e446844efa7749bf5eb878f8f7c0e46f4c')
+
+prepare() {
+ mkdir -p build
+
+ sed -e 's|GROUP="plugdev", MODE="0666"|TAG+="uaccess"|' -i indi-$pkgver/libindi/drivers/*/*.rules
+}
+
+build() {
+ cd build
+ cmake ../indi-$pkgver/libindi \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DUDEVRULES_INSTALL_DIR=/usr/lib/udev/rules.d
+ make
+}
+
+package() {
+ cd build
+ make DESTDIR="$pkgdir" install
+}
Property changes on: libindi/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list