[arch-commits] Commit in tp_smapi/repos (2 files)

Jan Steffens heftig at archlinux.org
Tue Nov 21 13:26:17 UTC 2017


    Date: Tuesday, November 21, 2017 @ 13:26:15
  Author: heftig
Revision: 267795

archrelease: copy trunk to community-staging-x86_64

Added:
  tp_smapi/repos/community-staging-x86_64/
  tp_smapi/repos/community-staging-x86_64/PKGBUILD
    (from rev 267794, tp_smapi/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: tp_smapi/repos/community-staging-x86_64/PKGBUILD (from rev 267794, tp_smapi/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2017-11-21 13:26:15 UTC (rev 267795)
@@ -0,0 +1,44 @@
+# Maintainer: Lukas Fleischer <lfleischer at archlinux.org>
+# Contributor: xduugu
+# Contributor: nh2
+# Contributor: Steven Davidovitz <steviedizzle ð gmail đ com>
+# Contributor: Nick B <Shirakawasuna ð gmail đ com>
+# Contributor: Christof Musik <christof ð senfdax đ de>
+# Contributor: Stefan Rupp <archlinux ð stefanrupp đ de>
+# Contributor: Ignas Anikevicius <anikevicius ð gmail đ com>
+
+pkgname=tp_smapi
+_pkgname=tp-smapi
+pkgver=0.42
+_extradir=/usr/lib/modules/extramodules-4.14-ARCH
+pkgrel=34
+pkgdesc="Modules for ThinkPad's SMAPI functionality"
+arch=('x86_64')
+url='https://github.com/evgeni/tp_smapi'
+license=('GPL')
+depends=('linux>=4.14' 'linux<4.15')
+makedepends=('linux-headers>=4.14' 'linux-headers<4.15')
+source=("$pkgname-$_pkgname-$pkgver.tar.gz::https://github.com/evgeni/$pkgname/archive/$_pkgname/$pkgver.tar.gz")
+md5sums=('6a51d3aa459ad7a6ebfbb8c29527b3ee')
+
+build() {
+  cd $pkgname-$_pkgname-$pkgver
+
+  # https://bugs.archlinux.org/task/54975 (kernel has no _GLOBAL_OFFSET_TABLE_):
+  # Clear EXTRA_CFLAGS since it defaults to injecting CFLAGS and -fno-plt breaks the modules
+
+  make HDAPS=1 KVER="$(<$_extradir/version)" EXTRA_CFLAGS=
+}
+
+package() {
+  cd $pkgname-$_pkgname-$pkgver
+
+  # install kernel modules
+  find . -name "*.ko" -exec install -Dt "$pkgdir$_extradir" {} +
+
+  # compress kernel modules
+  find "$pkgdir" -name "*.ko" -exec gzip -n -9 {} +
+
+  # load module on startup
+  echo tp_smapi | install -Dm644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/$pkgname.conf"
+}


More information about the arch-commits mailing list