[arch-commits] Commit in enchant/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Jan de Groot]

    Date: Wednesday, November 22, 2017 @ 09:33:25
  Author: jgc
Revision: 310534

archrelease: copy trunk to staging-x86_64

Added:
  enchant/repos/staging-x86_64/
  enchant/repos/staging-x86_64/PKGBUILD
    (from rev 310533, enchant/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: enchant/repos/staging-x86_64/PKGBUILD (from rev 310533, enchant/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2017-11-22 09:33:25 UTC (rev 310534)
@@ -0,0 +1,42 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at gmail.com>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: dorphell <dorphell at archlinux.org>
+
+pkgname=enchant
+pkgver=2.1.2
+pkgrel=1
+pkgdesc="A wrapper library for generic spell checking"
+arch=('x86_64')
+url="https://abiword.github.io/enchant/"
+license=('LGPL')
+depends=('aspell' 'hunspell' 'hspell' 'libvoikko' 'glib2')
+makedepends=('git')
+_commit=9889e6350eb645feca2b0c061f719ca4188984d5  # tags/v2.1.2
+source=("git+https://github.com/AbiWord/enchant.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/\./g'
+}
+
+prepare() {
+  cd $pkgname
+  ./bootstrap
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr \
+    --disable-static \
+    --disable-ispell \
+    --with-myspell-dir=/usr/share/myspell
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="${pkgdir}" install
+}