[arch-commits] Commit in wt/repos (2 files)

[Felix Yan]

    Date: Wednesday, November 22, 2017 @ 12:12:34
  Author: felixonmars
Revision: 267943

archrelease: copy trunk to community-staging-x86_64

Added:
  wt/repos/community-staging-x86_64/
  wt/repos/community-staging-x86_64/PKGBUILD
    (from rev 267942, wt/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: wt/repos/community-staging-x86_64/PKGBUILD (from rev 267942, wt/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2017-11-22 12:12:34 UTC (rev 267943)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+# Contributor: Denis Martinez <deuns.martinez at gmail.com>
+
+pkgname=wt
+pkgver=4.0.0
+pkgrel=2
+pkgdesc="a C++ library and application server for developing and deploying web applications"
+arch=('x86_64')
+url="http://www.webtoolkit.eu/"
+license=('GPL')
+depends=('boost-libs' 'libharu' 'graphicsmagick' 'pango' 'zlib')
+makedepends=('boost' 'cmake' 'postgresql-libs' 'fcgi' 'sqlite' 'mysql++' 'qt4' 'doxygen' 'mesa' 'glu')
+optdepends=('openssl: for SSL support in built-in webserver'
+	    'fcgi: for FastCGI support'
+	    'postgresql-libs: for PostgreSQL Dbo support'
+	    'sqlite: for Sqlite Dbo support'
+	    'mysql++: for the hangman example'
+	    'qt4: for the Wt/Qt interopability example (wtwithqt)')
+backup=('etc/wt/wt_config.xml')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/kdeforche/wt/archive/${pkgver}.tar.gz")
+sha512sums=('b8258e878950d0426d6502d6a4b61383e6c838a0cf696a7ccd168091a5b6043e666ccf54fe4c418ed47ef2392ff7aa5ba3da233e7c0fb4b2a3267b73851fb83c')
+
+build() {
+  cd "$srcdir"/${pkgname}-${pkgver}
+
+  [[ -d build ]] && rm -r build
+  mkdir -p build && cd build
+  cmake \
+      -DCONNECTOR_HTTP=ON \
+      -DWT_CPP_11_MODE=-std=c++11 \
+      -DWT_WRASTERIMAGE_IMPLEMENTATION=GraphicsMagick \
+      -DCMAKE_INSTALL_PREFIX=/usr \
+      -DWEBUSER=http \
+      -DWEBGROUP=http \
+      -DUSE_SYSTEM_SQLITE3=ON \
+      -DINSTALL_EXAMPLES=ON \
+      -DBUILD_EXAMPLES=ON \
+      -DINSTALL_FINDWT_CMAKE_FILE=ON \
+      ..
+  make
+}
+
+package() {
+  cd "$srcdir"/${pkgname}-${pkgver}/build
+
+  make DESTDIR="$pkgdir" install
+}