[arch-commits] Commit in gnome-builder/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Jan de Groot]

    Date: Wednesday, November 22, 2017 @ 14:24:27
  Author: jgc
Revision: 310600

archrelease: copy trunk to staging-x86_64

Added:
  gnome-builder/repos/staging-x86_64/
  gnome-builder/repos/staging-x86_64/PKGBUILD
    (from rev 310599, gnome-builder/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: gnome-builder/repos/staging-x86_64/PKGBUILD (from rev 310599, gnome-builder/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2017-11-22 14:24:27 UTC (rev 310600)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-builder
+pkgver=3.26.2
+pkgrel=2
+pkgdesc="An IDE for writing GNOME-based software"
+url="https://wiki.gnome.org/Apps/Builder"
+arch=(x86_64)
+license=(GPL3)
+depends=(gtksourceview3 devhelp libgit2-glib gjs python-gobject clang desktop-file-utils
+         ctags libpeas vte3 vala python-jedi autoconf-archive sysprof flatpak gspell libdazzle
+         template-glib jsonrpc-glib python-sphinx)
+makedepends=(intltool llvm gobject-introspection gtk-doc yelp-tools appstream-glib vala git
+             mm-common meson)
+optdepends=('gnome-code-assistance: Legacy assistance services')
+groups=(gnome-extra)
+_commit=516db20f41e8e213110d636070bda42731a10040  # tags/3.26.2^0
+source=("git+https://git.gnome.org/browse/gnome-builder#commit=$_commit"
+        "git+https://git.gnome.org/browse/libgd"
+        "git+https://git.gnome.org/browse/jsonrpc-glib"
+        "git+https://git.gnome.org/browse/template-glib"
+        "git+https://git.gnome.org/browse/libdazzle")
+sha256sums=('SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^GNOME_BUILDER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  mkdir build
+  cd $pkgname
+  git submodule init
+  git config --local submodule.subprojects/libgd.url "$srcdir/libgd"
+  git config --local submodule.subprojects/jsonrpc-glib.url "$srcdir/jsonrpc-glib"
+  git config --local submodule.subprojects/template-glib.url "$srcdir/template-glib"
+  git config --local submodule.subprojects/libdazzle.url "$srcdir/libdazzle"
+  git submodule update
+}
+
+build() {
+  cd build
+  arch-meson ../$pkgname
+  ninja
+}
+
+package() {
+  cd build
+  DESTDIR="$pkgdir" ninja install
+}