[arch-commits] Commit in networkmanager-openvpn/repos (2 files)

Jan Steffens heftig at archlinux.org
Wed Nov 22 15:14:39 UTC 2017


    Date: Wednesday, November 22, 2017 @ 15:14:37
  Author: heftig
Revision: 310613

archrelease: copy trunk to staging-x86_64

Added:
  networkmanager-openvpn/repos/staging-x86_64/
  networkmanager-openvpn/repos/staging-x86_64/PKGBUILD
    (from rev 310612, networkmanager-openvpn/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: networkmanager-openvpn/repos/staging-x86_64/PKGBUILD (from rev 310612, networkmanager-openvpn/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2017-11-22 15:14:37 UTC (rev 310613)
@@ -0,0 +1,41 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=networkmanager-openvpn
+pkgver=1.8.1dev+10+ge4d8cda
+pkgrel=2
+pkgdesc="NetworkManager VPN plugin for OpenVPN"
+url="https://wiki.gnome.org/Projects/NetworkManager"
+arch=(x86_64)
+license=(GPL)
+depends=(libnm libsecret openvpn)
+makedepends=(libnm-gtk intltool python git)
+_commit=e4d8cda14483b3195dbf2a9d61c565f426108ea3  # master
+source=("git+https://git.gnome.org/browse/network-manager-openvpn#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd network-manager-openvpn
+  git describe --tags | sed 's/-dev/dev/;s/-/+/g'
+}
+
+prepare() {
+  cd network-manager-openvpn
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd network-manager-openvpn
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --libexecdir=/usr/lib --disable-static
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd network-manager-openvpn
+  make DESTDIR="$pkgdir" install
+  echo 'u nm-openvpn - "NetworkManager OpenVPN"' |
+    install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
+}


More information about the arch-commits mailing list