[arch-commits] Commit in mailcap/trunk (PKGBUILD)

Jan Steffens heftig at archlinux.org
Thu Nov 23 07:32:19 UTC 2017


    Date: Thursday, November 23, 2017 @ 07:32:18
  Author: heftig
Revision: 310724

2.1.48+14+g5811758-1

Added:
  mailcap/trunk/PKGBUILD

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Added: PKGBUILD
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2017-11-23 07:32:18 UTC (rev 310724)
@@ -0,0 +1,37 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=mailcap
+pkgver=2.1.48+14+g5811758
+pkgrel=1
+pkgdesc="Helper application and MIME type associations for file types"
+url="https://pagure.io/mailcap"
+arch=(any)
+license=(MIT)
+makedepends=(git)
+checkdepends=(python)
+provides=(mime-types)
+conflicts=(mime-types)
+replaces=(mime-types)
+backup=(etc/mailcap
+        etc/mime.types
+        etc/nginx/mime.types)
+_commit=58117584fa573c92d918245d38269cc63cec5996  # master
+source=("git+https://pagure.io/mailcap#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd mailcap
+  git describe --tags | sed 's/^r//;s/-/./;s/-/./;s/-/+/g'
+}
+
+check() {
+  cd mailcap
+  make check
+}
+
+package() {
+  cd mailcap
+  make install DESTDIR="$pkgdir" sysconfdir=/etc mandir=/usr/share/man
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}


Property changes on: mailcap/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list