[arch-commits] Commit in bluegriffon-i18n/repos (2 files)
Fabio Castelli
muflone at archlinux.org
Sat Nov 25 20:34:52 UTC 2017
Date: Saturday, November 25, 2017 @ 20:34:51
Author: muflone
Revision: 268475
archrelease: copy trunk to community-testing-any
Added:
bluegriffon-i18n/repos/community-testing-any/
bluegriffon-i18n/repos/community-testing-any/PKGBUILD
(from rev 268474, bluegriffon-i18n/trunk/PKGBUILD)
----------+
PKGBUILD | 64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 64 insertions(+)
Copied: bluegriffon-i18n/repos/community-testing-any/PKGBUILD (from rev 268474, bluegriffon-i18n/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD (rev 0)
+++ community-testing-any/PKGBUILD 2017-11-25 20:34:51 UTC (rev 268475)
@@ -0,0 +1,64 @@
+# $Id$
+# Maintainer: Muflone http://www.muflone.com/contacts/english/
+# Contributor: Balló György <ballogyor+arch at gmail.com>
+# Contributor: Thomas Baechler <thomas at archlinux.org>
+# Contributor: Jaroslaw Swierczynski <swiergot at juvepoland.com>
+# Contributor: Michal Hybner <dta081 at gmail.com>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgbase=bluegriffon-i18n
+pkgname=()
+pkgver=2.4
+pkgrel=1
+pkgdesc="The next-generation Web Editor based on the rendering engine of Firefox"
+arch=('any')
+url="http://bluegriffon.org/"
+license=('MPL' 'GPL' 'LGPL')
+depends=("bluegriffon>=${pkgver}")
+groups=('bluegriffon')
+provides=('bluegriffon-i18n')
+source=("http://bluegriffon.org/freshmeat/${pkgver}/bluegriffon-${pkgver}.Ubuntu16.04-${CARCH}.tar.bz2")
+sha256sums=('ed3ef933aafb768afe420af65ad13b5eb98550bb792f9f385bcb6910fa52f614')
+
+_languages=(
+ 'cs "Czech"'
+ 'de "German"'
+ 'es-ES "Spanish (España)"'
+ 'fi "Finnish"'
+ 'fr "French"'
+ 'gl "Galego (España)"'
+ 'he "Hebrew"'
+ 'hu "Hungarian"'
+ 'it "Italian"'
+ 'ja "Japanese"'
+ 'ko "Korean"'
+ 'nl "Dutch"'
+ 'pl "Polish"'
+ 'ru "Russian"'
+ 'sl "Slovenian"'
+ 'sr "Russian"'
+ 'sv-SE "Svenska"'
+ 'zh-CN "Chinese Simplified"'
+ 'zh-TW "Traditional Chinese"'
+)
+
+for _lang in "${_languages[@]}"
+do
+ _locale="${_lang%% *}"
+ _pkgname="${pkgbase}-${_locale,,}"
+
+ pkgname+=("${_pkgname}")
+ eval "package_${_pkgname}() {
+ _package ${_lang}
+ }"
+done
+
+_package() {
+ _locale="$1"
+ _language="$2"
+ pkgdesc="${_language} language pack for Bluegriffon"
+
+ cd "bluegriffon/distribution/extensions"
+ install -m 755 -d "${pkgdir}/usr/lib/bluegriffon/distribution/extensions"
+ install -m 644 -t "${pkgdir}/usr/lib/bluegriffon/distribution/extensions" "langpack-${_locale}@bluegriffon.org.xpi"
+}
More information about the arch-commits
mailing list