[arch-commits] Commit in libtool/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Bartłomiej Piotrowski
bpiotrowski at archlinux.org
Sun Nov 26 22:06:07 UTC 2017
Date: Sunday, November 26, 2017 @ 22:06:06
Author: bpiotrowski
Revision: 310972
archrelease: copy trunk to testing-x86_64
Added:
libtool/repos/testing-x86_64/
libtool/repos/testing-x86_64/PKGBUILD
(from rev 310971, libtool/trunk/PKGBUILD)
----------+
PKGBUILD | 51 +++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 51 insertions(+)
Copied: libtool/repos/testing-x86_64/PKGBUILD (from rev 310971, libtool/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2017-11-26 22:06:06 UTC (rev 310972)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: judd <jvinet at zeroflux.org>
+
+# NOTE: requires rebuilt with each new gcc version
+
+pkgname=libtool
+pkgver=2.4.6+40+g6ca5e224
+pkgrel=2
+_gccver=7.2.1
+pkgdesc='A generic library support script'
+arch=(x86_64)
+url='http://www.gnu.org/software/libtool"'
+license=(GPL)
+groups=(base-devel)
+depends=(sh tar glibc)
+makedepends=("gcc=$_gccver" git help2man)
+provides=("libltdl=$pkgver" "libtool-multilib=$pkgver")
+conflicts=('libltdl' 'libtool-multilib')
+replaces=('libltdl' 'libtool-multilib')
+_commit=6ca5e224bc7bcc114a9ba2cf5dcf0fbf0ec40c9f
+source=(git+https://git.savannah.gnu.org/git/libtool.git#commit=$_commit)
+md5sums=('SKIP')
+
+
+pkgver() {
+ cd libtool
+ git describe --tags | sed 's/-/+/g;s/^v//'
+}
+
+prepare() {
+ cd libtool
+ ./bootstrap
+}
+
+build() {
+ cd libtool
+ ./configure --prefix=/usr lt_cv_sys_lib_dlsearch_path_spec="/usr/lib /usr/lib32"
+ make
+}
+
+check() {
+ cd libtool
+ make check || :
+}
+
+package() {
+ cd libtool
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list