[arch-commits] Commit in (4 files)

Felix Yan felixonmars at archlinux.org
Tue Nov 28 05:15:46 UTC 2017


    Date: Tuesday, November 28, 2017 @ 05:15:44
  Author: felixonmars
Revision: 270424

addpkg: haskell-logging-facade 0.3.0-1

Added:
  haskell-logging-facade/
  haskell-logging-facade/repos/
  haskell-logging-facade/trunk/
  haskell-logging-facade/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: haskell-logging-facade/trunk/PKGBUILD
===================================================================
--- haskell-logging-facade/trunk/PKGBUILD	                        (rev 0)
+++ haskell-logging-facade/trunk/PKGBUILD	2017-11-28 05:15:44 UTC (rev 270424)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=logging-facade
+pkgname=haskell-logging-facade
+pkgver=0.3.0
+pkgrel=1
+pkgdesc="Simple logging abstraction that allows multiple back-ends"
+url="https://github.com/sol/logging-facade"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-call-stack')
+makedepends=('ghc' 'haskell-hspec')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('3a6fbd7b309f6094224f6af2b98408a2a49519f8c0ca1a26178fc6c0b593af2101769a4981bcf250dab2ed99144ec14b19263a755e8c71a5b01400651076228f')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


Property changes on: haskell-logging-facade/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property


More information about the arch-commits mailing list