[arch-commits] Commit in (4 files)

Felix Yan felixonmars at archlinux.org
Tue Nov 28 10:41:16 UTC 2017


    Date: Tuesday, November 28, 2017 @ 10:41:15
  Author: felixonmars
Revision: 270469

addpkg: haskell-doctest 0.13.0-1

Added:
  haskell-doctest/
  haskell-doctest/repos/
  haskell-doctest/trunk/
  haskell-doctest/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: haskell-doctest/trunk/PKGBUILD
===================================================================
--- haskell-doctest/trunk/PKGBUILD	                        (rev 0)
+++ haskell-doctest/trunk/PKGBUILD	2017-11-28 10:41:15 UTC (rev 270469)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=doctest
+pkgname=haskell-doctest
+pkgver=0.13.0
+pkgrel=1
+pkgdesc="Test interactive Haskell examples"
+url="https://github.com/sol/doctest"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-compat' 'haskell-ghc' 'haskell-syb' 'haskell-code-page'
+         'haskell-ghc-paths')
+makedepends=('ghc' 'haskell-hunit' 'haskell-hspec' 'haskell-quickcheck' 'haskell-stringbuilder'
+             'haskell-silently' 'haskell-setenv' 'haskell-with-location' 'haskell-mockery')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('6ae0cc74811501cc8d94c50a1de2ae241e298a3bdc56ef21a1b0c5f6ad05b3119efbafb1e3d286c1aee59c9884f364c04ecc8e4505ac54d9c8319b3402a92644')
+
+prepare() {
+    # Add -dynamic flag
+    sed -i '/-packageghc/a \  , "-dynamic"' $_hkgname-$pkgver/test/doctests.hs
+    sed -i 's/Example.hs"/Example.hs", "-dynamic"/' $_hkgname-$pkgver/src/Run.hs
+}
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


Property changes on: haskell-doctest/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property


More information about the arch-commits mailing list