[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Tuesday, November 28, 2017 @ 10:57:33
  Author: felixonmars
Revision: 270479

addpkg: haskell-hjsonschema 1.7.1-1

Added:
  haskell-hjsonschema/
  haskell-hjsonschema/repos/
  haskell-hjsonschema/trunk/
  haskell-hjsonschema/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: haskell-hjsonschema/trunk/PKGBUILD
===================================================================
--- haskell-hjsonschema/trunk/PKGBUILD	                        (rev 0)
+++ haskell-hjsonschema/trunk/PKGBUILD	2017-11-28 10:57:33 UTC (rev 270479)
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hjsonschema
+pkgname=haskell-hjsonschema
+pkgver=1.7.1
+pkgrel=1
+pkgdesc="JSON Schema library"
+url="https://github.com/seagreen/hjsonschema"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-file-embed' 'haskell-hashable' 'haskell-hjsonpointer'
+         'haskell-http-client' 'haskell-http-types' 'haskell-pcre-heavy' 'haskell-profunctors'
+         'haskell-protolude' 'haskell-quickcheck' 'haskell-scientific' 'haskell-semigroups'
+         'haskell-unordered-containers' 'haskell-text' 'haskell-vector')
+makedepends=('ghc' 'haskell-hspec' 'haskell-wai-app-static' 'haskell-warp')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('fb275959e0129cea9af7e0539f0d63cfda6ad4aabb371d223825f679885c4122909181ec98ddeec312256198c62b7b411a51b080942d74682b5a21f3858e163c')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "MIT-LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/MIT-LICENSE.txt"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/MIT-LICENSE.txt"
+}


Property changes on: haskell-hjsonschema/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property