[arch-commits] Commit in (4 files)

Felix Yan felixonmars at archlinux.org
Wed Nov 29 17:21:54 UTC 2017


    Date: Wednesday, November 29, 2017 @ 17:21:54
  Author: felixonmars
Revision: 270738

addpkg: haskell-quickcheck-assertions 0.3.0-1

Added:
  haskell-quickcheck-assertions/
  haskell-quickcheck-assertions/repos/
  haskell-quickcheck-assertions/trunk/
  haskell-quickcheck-assertions/trunk/PKGBUILD

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Added: haskell-quickcheck-assertions/trunk/PKGBUILD
===================================================================
--- haskell-quickcheck-assertions/trunk/PKGBUILD	                        (rev 0)
+++ haskell-quickcheck-assertions/trunk/PKGBUILD	2017-11-29 17:21:54 UTC (rev 270738)
@@ -0,0 +1,43 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=quickcheck-assertions
+pkgname=haskell-quickcheck-assertions
+pkgver=0.3.0
+pkgrel=1
+pkgdesc="HUnit like assertions for QuickCheck"
+url="https://github.com/s9gf4ult/quickcheck-assertions"
+license=("LGPL")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck' 'haskell-ieee754' 'haskell-pretty-show')
+makedepends=('ghc' 'haskell-hspec')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('7a7a2d503ef270b4b6dcb1665bd1b83e0f7f3477b7fb714ed4685d96bb5e2244f5fd2d833d2f3e9284e7adc0fef5b4547a7182d542c3848a96dce540af207564')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


Property changes on: haskell-quickcheck-assertions/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property


More information about the arch-commits mailing list